两种快速打印 Outlook 电子邮件中所有表格的方法

如果您想快速打印 Outlook 电子邮件中没有其他文本的所有表格，您可以使用两种方法中的任何一种来完成它。

当您收到一封在邮件正文中包含许多表格的电子邮件时，有时您可能希望提取这些表格并只打印出来，而不是正文中的文本。 但是outlook没有相关功能可以实现。 因此，在下文中，我们将向您分享2种方法。

方法 1：在单独的页面中打印所有表格

1. 首先，启动 Outlook 程序。
2. 然后在 Outlook 主窗口中，按“Alt + F11”键按钮。
3. 在随后的“Microsoft Visual Basic for Applications”窗口中，您可以找到并打开一个未使用的模块。
4. 之后，您应该将以下 VBA 代码复制到此模块中。

Sub PrintAllTables_inOutlookEmail_Individually()
    Dim objMail As Outlook.MailItem
    Dim objMailDocument As Word.Document
    Dim objTable As Word.Table
    Dim lTableCount As Long
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim i As Long
 
    'Get the Source Mail
    Set objMail = Outlook.Application.ActiveExplorer.Selection.Item(1)
    Set objMailDocument = objMail.GetInspector.WordEditor
    lTableCount = objMailDocument.Tables.count
 
    Set objWordApp = CreateObject("Word.Application")
    objWordApp.Visible = True
 
    For i = 1 To lTableCount
        Set objTable = objMailDocument.Tables(i)
        objTable.Range.Copy
 
        'Copy Each Table into Each Word Document
        Set objWordDocument = objWordApp.Documents.Add
        objWordDocument.Content.Paste
 
        'Print Out Each Document
        objWordDocument.PrintOut
 
        objWordDocument.Close False
    Next
 
    objWordApp.Quit
End Sub

5. 稍后您应该将新的 VBA 项目添加到快速访问工具栏。 前往“Outlook选项”>“快速访问工具栏”选项卡来实现它。
6. 终于可以拍了。

• 首先，选择一封包含多个表格的电子邮件。
• 然后单击快速访问工具栏中的新宏按钮。
• 所有表格将立即打印在单独的页面中。

方法 2：依次打印所有表

1. 首先，按照上述方法的步骤 1 到 2 前往“Microsoft Visual Basic for Applications”窗口。
2. 然后访问一个未使用的模块，您需要将以下 VBA 代码复制到其中。

Sub PrintAllTables_inOutlookEmail_Continuously()
    Dim objMail As Outlook.MailItem
    Dim objMailDocument As Word.Document
    Dim objTable As Word.Table
    Dim lTableCount As Long
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objCell As Word.Cell
 
    Set objMail = Outlook.Application.ActiveExplorer.Selection.Item(1)
    Set objMailDocument = objMail.GetInspector.WordEditor
 
    'Create a Word Document
    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Add
    objWordDocument.Activate
    objWordApp.Visible = True
 
    For Each objTable In objMailDocument.Tables
        objTable.Range.Copy
 
        'Copy All Tables into One Word Document
        With objWordDocument.Range
             .Collapse wdCollapseEnd
             .PasteSpecial wdPasteRTF
             .Text = vbCrLf
        End With
    Next
 
    'Print out the Word Document
    objWordDocument.PrintOut
    objWordDocument.Close False
    objWordApp.Quit
End Sub

3. 稍后您可以将新宏添加到快速访问工具栏。
4. 最后，您选择一个源邮件并点击快速访问工具栏中的宏按钮。 立即，此电子邮件中的所有表格将被复制到一个 Word 文档中，现在将打印出来。

保护 Outlook 数据免受损坏

尽管具有众多功能，但 Outlook 无法避免错误、崩溃和损坏。 因此，一旦遇到死机，你的Outlook数据往往会和你告别。 因此，为了防止 前景腐败，您需要做一些努力，例如阻止隐藏的病毒，保持正常关闭 Outlook 等。 另外，最好使用经验丰富的维修工具，例如 DataNumen Outlook Repair.

作者简介：

Shirley Zhang 是一位数据恢复专家 DataNumen, Inc.，它是数据恢复技术领域的世界领先者，包括 修复 mdf 和 outlook 修复软件产品。 欲了解更多信息，请访问 datanumen.comc