删除 Word 表格中空白行和列的 3 种快速方法

在这个post，我们将向您解释 3 种快速删除 Word 表格中的空白行和列的方法。

表格对于文档来说是必不可少的，尤其是在保存各种类型的数据时。 有时，一个长表可能会超过一页并延伸到几页。 因此，一旦表格变得又长又复杂，您可以采取一些措施来简化它。 例如，您可以删除不需要的空白行和列。

以下是您可以使用的 3 种方法。

方法一：手动删除空白行和列

1. 首先在空白处选择一行或一列。
2. 然后右键单击以获取上下文菜单。 在菜单上，相应地选择“删除行”或“删除列”。

不幸的是，您不能选择多个不连续的行或列并用这种方式将它们一起删除。 这个需求可以参考我们之前的文章： 批量删除 Word 表格中多行或多列的 5 种快速方法

方法二：批量删除表格中的所有空白行和列

方法 1 有其局限性。 因此，我们将为您提供通过 VBA 代码批量删除表格中的行和列的方法。

1. 首先，将光标放在 tar得到表。
2. 其次，按“Alt+F11”触发 VBA 编辑器。
3. 在编辑器中，先点击“Normal”项目。
4. 然后单击菜单栏上的“插入”选项卡。
5. 在下拉菜单中，选择“模块”。
6. 双击模块打开它并粘贴以下代码：

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. 最后，单击菜单栏上的“运行”按钮或按“F5”。

几秒钟后，您将删除该表中的所有空白行和列。

方法三：批量删除文档中所有表格的所有空白行和列

1. 首先，重复方法 2 中的步骤来安装和运行宏。
2. 只是这一次，将该宏替换为以下内容：

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

恢复损坏的文件

检索 l 的方法不止一种ost 现在数据回来了。 例如，诉诸备份始终是您的首要任务。 如果这不能满足您获取最新信息的需要，您可以尝试 文档修复 工具。

作者简介：

Vera Chen 是一位数据恢复专家 DataNumen, Inc.，它是数据恢复技术领域的世界领先者，包括 xlsx修复 以及 pdf 修复软件产品。 欲了解更多信息，请访问 datanumen.com