2种方法批量删除Outlook中没有电子邮件地址的所有联系人

如果您发现某些联系人在您的 Outlook 中没有电子邮件地址，您可能需要处理每个联系人文件夹以删除所有此类联系人。 这个ost 将与您分享2种方式。

也许您的 Outlook 中有很多联系人，其中一些没有电子邮件地址。 如果您认为它们不再有用，您一定希望删除所有没有电子邮件地址的联系人。 在标准方式下，您可以使用“即时搜索”找到它们，然后手动删除它们，就像下面的方法一。但是，它有点繁琐。 因此，在方法二中，我们将教您另一种更高效的方法。

方法一：找到没有邮箱的联系人后手动删除

1. 对于作为tart、按“Ctrl+3”键访问“联系人”面板。
2. 然后，单击搜索框。
3. 接下来，在出现的“搜索”功能区中，单击“所有联系人项目”。
4. 随后，单击“有地址”>“有电子邮件地址”。
5. 之后，“NOT emailaddresses:=[]”条件将添加到搜索框中。 您需要删除“NOT”。
6. 随后，将列出所有没有电子邮件地址的联系人。
7. 现在，您应该在搜索结果中手动选择联系人，因为您的联系人组也必须在列表中。
8. 最后，按“Del”键按钮删除所有选中的联系人。

方法二：用VBA批量删除所有没有邮箱的联系人

1. 首先，点击“Alt + F11”在 Outlook 中启动 VBA 编辑器。
2. 在新屏幕中，将以下 VBA 代码复制到模块中。

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. 稍后，单击“BatchDeleteAllContactsWithoutEmailAddress”子程序。
4. 最后，按“F5”来触发这个宏。
5. 完成后，您会收到有关结果的消息，如下图所示。
6. 所有没有电子邮件地址的联系人都已移至“已删除邮件”文件夹。

远离一切潜在风险

Outlook 可能会由于多种因素而损坏，例如病毒、用户错误、软件故障以及硬件故障。 您一定不愿意遭受 Outlook 损坏，因此您需要将所有这些潜在风险拒之门外。 例如，您需要在 PC 上安装强大的防病毒软件。 另外，您必须定期备份 Outlook 数据。 最后但同样重要的是，你最好准备一个强大可靠的修复工具，比如 DataNumen Outlook Repair. 它可以修复你的 损坏的 PST 文件轻松。

作者简介：

Shirley Zhang 是一位数据恢复专家 DataNumen, Inc.，它是数据恢复技术领域的世界领先者，包括 SQL Server 腐败 和 outlook 修复软件产品。 欲了解更多信息，请访问 datanumen.com