如何快速将“收藏夹”部分中的所有 Outlook 文件夹和项目导出到 Windows 文件夹

如果您想导出所有 Outlook 文件夹及其在“收藏夹”部分中的项目，您可以参考这篇文章。 在这里，我们将向您展示如何快速完成它。

通常，“收藏夹”部分中的文件夹及其项目非常重要且经常需要。 因此，有时您可能希望将它们导出到本地驱动器。 按照标准方式，您必须根据“收藏夹”中的文件夹创建 Windows 文件夹，并将项目一个一个地保存为 MSG 文件在本地驱动器中。 那太乏味了。 因此，在这里我们将公开一种更有效的方法。 现在继续阅读以了解它。

将“收藏夹”部分中的所有文件夹和项目导出到 Windows 文件夹

1. 首先，通过参考“访问 Outlook 中的 VBA 编辑器”如何在 Outlook 中运行 VBA 代码“。
2. 然后，将以下代码复制到一个空模块中。

Sub ExportAllFoldersItems_InFavorites_ToWindowsFolder()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFileSystem As Object
    Dim strWindowsFolder As String
    Dim objNavigationPane As Outlook.NavigationPane
    Dim objNavigationModule As Outlook.NavigationModule
    Dim objNavigationGroup As Outlook.NavigationGroup
    Dim objNavigationFolder As Outlook.NavigationFolder
    Dim objFolder As Outlook.Folder
    Dim strFolderPath As String
    Dim objItem As Object
    Dim strFilePath As String
    Dim i As Long
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
     
       'Get "Favorites" section
       Set objNavigationPane = Application.ActiveExplorer.NavigationPane
       Set objNavigationModule = objNavigationPane.Modules.GetNavigationModule(olModuleMail)
       Set objNavigationGroup = objNavigationModule.NavigationGroups.GetDefaultNavigationGroup(olFavoriteFoldersGroup)
 
       'Export the folders and items in "Favorites" section
       For Each objNavigationFolder In objNavigationGroup.NavigationFolders
           Set objFolder = objNavigationFolder.Folder
           strFolderPath = strWindowsFolder & objFolder.Name
           objFileSystem.CreateFolder strFolderPath
 
           For Each objItem In objFolder.Items
               strSubject = objItem.Subject
               strFileName = strSubject & ".msg"
 
               i = 0
               Do Until False
                  strFilePath = strFolderPath & "\" & strFileName
                  If objFileSystem.FileExists(strFilePath) Then
                     i = i + 1
                     strFileName = strSubject & " (" & i & ").msg"
                  Else
                     Exit Do
                  End If
               Loop
 
               objItem.SaveAs strFilePath, olMSG
          Next
       Next
 
       'Open the Windows folder
       Call Shell("explorer.exe " & strWindowsFolder, vbNormalFocus)
    End If
End Sub

3. 然后，单击工具栏中的“运行”图标。
4. 接下来，在弹出的对话框中，选择目标 Windows 文件夹并单击“确定”。
5. 宏完成后，将显示 Windows 文件夹。
6. 在这个 Windows 文件夹中，“收藏夹”部分的文件夹及其项目已被导出，如下图所示。

从备份恢复 Outlook 数据

强烈建议定期备份 Outlook 文件。 这是因为如果您遭受 Outlook 文件损坏，您可以 恢复 Outlook 轻松备份数据。 但是，如果您没有这样的备份，则必须尝试艰难的 Outlook 修复。 那时，收件箱修复工具不会有太大帮助。 您必须借助修复外部工具，例如 DataNumen Outlook Repair.

作者简介：

Shirley Zhang 是一位数据恢复专家 DataNumen, Inc.，它是数据恢复技术领域的世界领先者，包括 损坏的sql 和 outlook 修复软件产品。 欲了解更多信息，请访问 datanumen.com