如何快速将多封Outlook邮件中的所有超链接导出到Excel

当你需要提取一封或多封电子邮件中的所有超链接时，一个一个地复制它们是愚蠢的。 这个ost 将教您一种快速将多封邮件中的所有超链接导出到Excel的方法。

由于某些原因，例如在您发送的所有电子邮件中记录超链接，您需要提取超链接。 毫无疑问，手动提取和复制它们是不可取的。 您一定渴望有一种更聪明的方法，例如使用 VBA。 在这里给大家分享这样一段VBA代码，可以将很多邮件中的超链接一键导出到Excel中。

将多封电子邮件中的所有超链接导出到 Excel

1. 到tar然后，照常启动您的 Outlook 程序。
2. 然后，在 Outlook 窗口中，您需要点击“Alt + F11”键按钮。
3. 您将立即访问 Outlook VBA 编辑器。
4. 随后，您需要启用“Microsoft Word Object Library”以及“Microsoft Excel 对象库rary”。 单击“工具”>“引用”，然后在弹出的对话框中启用它们。
5. 接下来，您需要打开一个未使用的模块，您必须在其中将下面的 VBA 代码复制到该模块中。

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. 之后，您可以退出当前的 VBA 编辑器窗口。
7. 稍后访问“Outlook 选项”自定义快速访问工具栏，将新添加的宏添加到快速访问工具栏。
8. 最后你可以拍一张：

• 首先，在电子邮件列表中，选择您要提取其超链接的电子邮件。
• 然后，单击快速访问工具栏中的宏按钮。
• 宏完成后，您将获得一个 Excel 文件，如下图所示：

修复意外的 Outlook 问题

Outlook 问题可能会不时发生，但没有任何预兆。 但是，就小错误而言，Outlook 可以通过简单的 res 恢复tart或其 收件箱维修工具. 但是如果遇到一些严重的麻烦，内部手段就起不到作用了。 在这一点上，你最后的选择肯定是一个更有信誉和更强大的工具，比如 DataNumen Outlook Repair.

作者简介：

Shirley Zhang 是一位数据恢复专家 DataNumen, Inc.，它是数据恢复技术领域的世界领先者，包括 损坏的中密度纤维板 和 outlook 修复软件产品。 欲了解更多信息，请访问 datanumen.com