Ovoz berish statistikasini Outlook elektron pochtasidan Excel ish varag'iga qanday tezda eksport qilish mumkin

Outlook yechimlari Sentyabr 29, 2025

Agar siz ovoz berish tugmalari bilan elektron pochta xabarini yuborgan bo'lsangiz, qabul qiluvchilar sizga javoblarini yuborgandan so'ng, ovoz berish statistikasini hisoblashingiz va Excel ish varag'iga eksport qilishingiz mumkin. Shunday qilib, ushbu postda biz sizga buni qanday qilib tezda amalga oshirishni o'rgatamiz.

Outlook shunchalik kuchliki, u hatto "Ovoz berish" funksiyasini ham taklif qiladi. Mening oldingi maqolam "Ovoz berish uchun MS Outlook dasturidan mohirona foydalanish"Undan qanday qilib samarali foydalanishni o'rgatdi. Bundan tashqari, ko'p hollarda, ovoz bergandan so'ng, siz ba'zi sabablarga ko'ra, masalan, statistikani chop etishni xohlasangiz, ovoz berish statistikasini Excel ish varag'iga eksport qilishingiz mumkin. Ammo Outlook buni sukut bo'yicha qo'llab-quvvatlamaydi. Shunday qilib, quyida biz sizga buni qanday amalga oshirishni o'rgatamiz.

Elektron pochta orqali ovoz berish statistikasini Excel ish varag'iga eksport qiling

Eng boshida Outlook ilovasini ishga tushiring.
Keyin asosiy Outlook oynasida "Alt + F11" tugmachalarini bosishingiz kerak.
Keyingi "Microsoft Visual Basic for Applications" oynasida "Microsoft Excel Object Library" ni yoqishingiz kerak. "Tools" > "Reference" ni bosing. Keyin ochilgan muloqot oynasida "Microsoft Excel Object Library" oldidagi katakchani belgilang va nihoyat "OK" tugmasini bosing.
Shundan so'ng siz yangi modulni kiritishingiz yoki foydalanilmaydigan modulni ochishingiz mumkin.
Keyinchalik, ushbu modulga quyidagi VBA kodlarini nusxa ko'chiring va joylashtiring.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Shundan so'ng, qulay kirish uchun siz tez kirish asboblar paneliga yangi makrosni qo'shsangiz yaxshi bo'ladi.
Oxir-oqibat, siz sinab ko'rishingiz mumkin.

Birinchidan, ovoz berish tugmalari mavjud manba elektron pochta manzilini tanlang.
Keyin Tez kirish asboblar panelidagi makros tugmasini bosing.
Ushbu makros ishga tushirilgandan so'ng, siz oldindan belgilangan mahalliy papkaga o'tishingiz mumkin, unda siz yangi Excel ish kitobini ko'rasiz.
Ushbu Excel ish kitobini oching. Endi siz quyidagi rasmda ko'rsatilgan ovoz berish statistikasini ko'rasiz:

Hech kim Outlook xatolarini to'liq bartaraf eta olmaydi

Outlook turli xil imkoniyatlarga ega bo'lsa-da, Outlook xatolarining oldini olishga yordam beradigan bunday xususiyat mavjud emas. Barcha turdagi omillar Outlook xatolariga olib kelishi mumkin. Misol uchun, agar siz tez-tez Outlook-dan noto'g'ri chiqib ketsangiz, siz azob chekishingiz mumkin PST buzilishi. Bunday stsenariyda sizning PST faylingizni qutqarish uchun ba'zi kuchli vositalardan foydalanishdan boshqa tanlovingiz yo'q. DataNumen Outlook Repair. Yuqori tiklanish darajasi tufayli u juda ko'p maqtovga sazovor bo'ldi.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc buzilgan mdf va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com