Qanday qilib bir nechta Outlook elektron pochta xabarlarini VBA orqali bitta so'zli hujjatga ommaviy eksport qilish mumkin

Agar siz bir nechta Outlook elektron pochta xabarlarini bitta so'zli hujjatga ommaviy eksport qilishni istasangiz, ushbu maqolada ko'rsatilgan VBA kodidan foydalanishingiz mumkin. Bu sizga bir necha soniya ichida bu vazifani bajarishga yordam beradi.

Men avvalgi maqolamda Outlook elektron pochtasini Word hujjatiga qanday o'zgartirish haqida gapirganman - "Outlook elektron pochtasini Word hujjatiga aylantirishning 2 ta samarali usullari”. Biroq, bu 2-bandda aytib o'tilgan ikkala vosita hamost Agar siz ko'plab elektron pochta xabarlarini bitta Word hujjatiga eksport qilmoqchi bo'lsangiz, yordamsiz bo'ladi. Shunday qilib, bu erda biz sizga boshqa yo'lni o'rgatamiz. Endi uni batafsilroq tushunish uchun o'qing.

Bir nechta Outlook elektron pochta xabarlarini bitta Word hujjatiga ommaviy eksport qilish

1. S gatart bilan Outlook dasturingizni ishga tushiring.
2. Keyin, asosiy Outlook oynasiga kirganingizdan so'ng, "Alt + F11" tugmachalarini bosishingiz kerak.
3. Keyin bo'sh modulni ochishingiz kerak bo'lgan Outlook VBA muharririga kirish huquqiga ega bo'lasiz.
4. Keyinchalik, ochilgan modul oynasiga quyidagi VBA kodini nusxalang.

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Shundan so'ng, ushbu yangi VBA loyihasini Tez kirish asboblar paneli yoki lentaga qo'shsangiz yaxshi bo'ladi.
6. Oxir-oqibat, siz sinab ko'rishingiz mumkin.

• Birinchi navbatda, bir nechta Outlook elektron pochta xabarlarini tanlang.
• Keyin toping va yangi qo'shilgan so'l tugmasini bosing.
• "Bajarildi" so'ralgandan so'ng, yangi Word hujjatini topish uchun oldindan belgilangan mahalliy papkaga o'tishingiz mumkin.
• Barcha tanlangan elektron pochta xabarlari eksport qilinganligini ko'rishingiz mumkin bo'lgan ushbu hujjatni oching.

Qudratli tiklash vositasini yaqin joyda saqlang

Ko'p funktsiyalardan qat'i nazar, Outlook hali ham xatolardan himoyalana olmaydi. Agar siz xatolarni yolg'iz qoldirishga odatlangan bo'lsangiz, ular yig'ilib qolganda, Outlook ishdan chiqishi aniq bo'ladi. Bunday holda, kuchli va samarali tiklash vositasiga murojaat qilish juda muhimdir DataNumen Outlook Repair. U yaxshi o'rganilgan PST tuzatish. U bilan birga ekan, siz endi prognoz ma'lumotlarining yo'qolishi haqida tashvishlanishingiz shart emas.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc buzilgan mdf va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com