Outlook elektron pochtasining barcha rasm qo'shimchalarini Excel ish varag'iga qanday tezda eksport qilish mumkin

Agar siz Outlook elektron pochtasining barcha rasm qo'shimchalarini tezda Excel ish varag'iga eksport qilmoqchi bo'lsangiz, ushbu maqolaga murojaat qilishingiz mumkin. Bu erda biz sizga qo'lda eksport qilishdan ko'ra samaraliroq yo'lni ko'rsatamiz.

ah o'z ichiga olgan elektron pochta xabarini olganingizdaost Rasm qo'shimchalari, agar siz ulardan Excelda hisobot tayyorlash uchun foydalanmoqchi bo'lsangiz, ushbu rasmlarni Excel ish varag'iga to'plamlarda eksport qilish yo'lini orzu qilishingiz kerak. Endi biz sizga bunday yondashuvni quyida tanishtiramiz.

Elektron pochtaning barcha rasm qo'shimchalarini Excel ish varag'iga eksport qiling

1. Boshlash uchun Outlook ilovangizga odatiy tarzda kiring.
2. Keyin, Outlook oynasida "Alt + F11" tugmachalarini bosing, bu esa "Ilovalar uchun Microsoft Visual Basic" oynasini ochadi.
3. Ushbu ekranda siz ishlatilmayotgan modulni ochishingiz yoki to'g'ridan-to'g'ri yangisini kiritishingiz kerak.
4. Keyinchalik, quyidagi VBA kodini ushbu modulga nusxalashingiz kerak.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Shundan so'ng siz makrosdan chiqishingiz mumkin.
6. Keyin, ushbu makrosni Tez kirish asboblar paneliga qo'shish uchun "Fayl" > "Tanlovlar" > "Tez kirish asboblar paneli" ga o'ting.
7. Nihoyat, siz hozir ushbu makroni sinab ko'rishingiz mumkin.

• Birinchidan, manba elektron pochta manzilini tanlang yoki oching.
• Keyin, Tez kirish asboblar panelidagi makros tugmasini bosing.
• Makros tugallangach, siz quyidagi skrinshotda ko'rsatilgan Excel ish varag'ini olasiz:

Outlook faylini buzilishdan himoya qiling

Ma'lumki, Outlook korruptsiyaga moyil. Shuning uchun biz Outlook korruptsiyasidan qanday himoya qilishni tushunishimiz kerak. Avvalo, virus hujumlarini blokirovka qilish uchun antivirus dasturini o'rnatish va hech qachon noma'lum qo'shimchani yuklab olish kerak. Bundan tashqari, biz kuchli ta'mirlash vositasini qo'lga kiritganimiz ma'qul DataNumen Outlook Repair. m taklif qilishi mumkinost hollarda samarali vosita Outlookning buzilishi.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc sqlni tiklash va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com