Outlook kontakt guruhidagi barcha a'zolarning ma'lumotlarini Excelga qanday tezda eksport qilish mumkin

Odatiy bo'lib, siz faqat kontakt guruhidagi a'zolar ismlari va elektron pochta manzillarini ko'rishingiz mumkin. Agar siz a'zolarning boshqa ma'lumotlarini olishni istasangiz, ushbu maqolada keltirilgan usuldan foydalanishingiz mumkin.

Kontakt guruhini ochish uchun uni ikki marta bosganingizda, uning oynasida siz faqat guruh a'zolarining ismlari va elektron pochta manzillarini ko'rishingiz mumkin. Siz a'zolarning kompaniya, lavozim nomi, telefon raqami yoki biznes manzili kabi boshqa ma'lumotlarini ololmayapsiz. Umuman olganda, bu ma'lumotlarni olish uchun siz "Kontaktlar" jildidan a'zolarga mos keladigan kontaktlarni qo'lda topishingiz kerak. Bu juda qiyin. Bu erda biz sizga VBA kodining bir qismini ko'rsatamiz, bu ma'lumotlarni tezda Excel ish kitobiga eksport qila oladi.

Kontakt guruhidagi barcha a'zolarning ma'lumotlarini Excelga eksport qiling

1. Boshlash uchun Outlook ilovangizni ishga tushiring.
2. Keyin asosiy Outlook oynasida "Alt + F11" tugmachalarini bosishingiz kerak.
3. Keyingi yangi "Ilovalar uchun Microsoft Visual Basic" oynasida siz ishlatilmaydigan modulni ochishingiz yoki to'g'ridan-to'g'ri yangi modulni kiritishingiz kerak.
4. Keyinchalik, ushbu modulga quyidagi VBA kodini nusxa ko'chiring va joylashtiring.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Shundan so'ng, qulay tekshirish uchun siz tez kirish asboblar paneli yoki lentaga yangi VBA loyihasini qo'shishingiz mumkin.
6. Keyinchalik Outlook makro xavfsizlik darajasini past darajaga o'rnating.
7. Oxir-oqibat, siz sinab ko'rishingiz mumkin.

• Birinchidan, kontaktlar guruhini tanlang.
• Keyin Tez kirish asboblar paneli yoki lentasidagi so'l tugmasini bosing.
• Darhol makro ishga tushadi.
• U tugagach, siz “Bajarildi!” degan xabarni olasiz.
• Shundan so'ng, oldindan belgilangan mahalliy papkaga o'tishingiz mumkin, unda siz yangi Excel faylini topishingiz mumkin.
• Uni oching, siz quyidagi skrinshot kabi guruh a'zolarining aloqa ma'lumotlarini ko'rasiz:

Outlook bilan bog'liq muammolar oldida vahima qo'ymang

Qalqib chiquvchi xato xabari yoki qanday bo'lishidan qat'i nazar, hech kim Outlook muammolarini qabul qilishga tayyor emas buzilgan Outlook ma'lumotlar fayli. Shuning uchun, foydalanuvchilar Outlook bilan bog'liq muammolarga duch kelganda vahima qo'zg'atadilar. Agar siz bu holatda xotirjam bo'lishni istasangiz, qo'lingizda ikkita zarurat bo'lishi kerak. Ulardan biri joriy Outlook ma'lumotlarining zaxira nusxalari. Ikkinchisi kuchli Outlook tuzatish dasturi, masalan DataNumen Outlook Repair.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc sqlni tiklash va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com