Windows papkasidagi oxirgi o'zgartirilgan faylni Outlook elektron pochtangizga qanday tezda biriktirish mumkin

Ba'zida siz Windows-ning ma'lum bir jildidagi oxirgi o'zgartirilgan faylni tezda topib, Outlook elektron pochtasiga biriktirishingiz mumkin. Bunday holda, siz ushbu maqolada keltirilgan usuldan foydalanishingiz mumkin.

Ba'zi foydalanuvchilar Outlook-ga Windows papkasidagi so'nggi o'zgartirilgan faylni, masalan, eng so'nggi yaratilgan, o'zgartirilgan yoki saqlangan faylni tezda topish va elektron pochtaga qo'shish imkonini berishni xohlashadi. Biroq, Outlook bunday to'g'ridan-to'g'ri va mahalliy xususiyatni taklif qilmaydi. Shuning uchun, quyida biz uni osongina amalga oshirish mumkin bo'lgan VBA kodining bir qismini taqdim etamiz.

Windows papkasida oxirgi o'zgartirilgan faylni elektron pochtaga biriktiring

1. Eng boshida Outlook ilovasini ishga tushirishingiz kerak.
2. Keyin, asosiy Outlook oynasiga kirganingizdan so'ng, "Alt + F11" tugmachalarini bosishingiz mumkin.
3. Keyin Outlook VBA muharriri oynasiga muvaffaqiyatli kirasiz.
4. Keyinchalik, siz foydalanilmayotgan modulni topishingiz va ochishingiz kerak.
5. Va keyin ushbu modul oynasiga quyidagi VBA kodini nusxa ko'chiring va joylashtiring.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Shundan so'ng, siz joriy VBA muharriri oynasidan chiqishingiz va yangi makrosni Tez kirish asboblar paneliga yoki xabarlar oynasi lentasiga qo'shishni davom ettirishingiz mumkin.
7. Keyinchalik Outlook makro xavfsizlik darajasini past darajaga o'zgartirishingiz kerak.
8. Oxir-oqibat, siz sinab ko'rishingiz mumkin.

• Birinchidan, odatdagidek yangi Outlook elektron pochtasini yarating va yozing.
• Keyin quyidagi rasmdagi kabi Tezkor kirish asboblar panelidagi makros tugmasini bosing:
• Keyin sizdan Windows-ning manba papkasini tanlashingiz va "OK" tugmasini bosishingiz talab qilinadi.
• Agar tanlangan Windows jildida shunday fayl mavjud bo'lsa, siz quyidagi skrinshotga o'xshash taklifni olasiz:
• “Ha” tugmasini bosganingizda, bu fayl birdaniga biriktiriladi.

Outlook muammolarini imkon qadar tezroq hal qiling

Har qanday Outlook muammosiga duch kelganingizda, ularni imkon qadar tezroq hal qilish tavsiya etiladi. Bunday vaziyatda siz mustahkamlovchi tayyorlaganingiz ma'qul Outlook tuzatish kabi oldindan vosita DataNumen Outlook Repair. U PST xatolarini tuzatishga va Outlook ma'lumotlarini samarali tarzda qutqarishga qodir.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc buzilgan mdf va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com