Outlook-dagi har xil turdagi bayroqchalar uchun birlamchi eslatma vaqtini qanday o'rnatish mumkin

Odatiy bo'lib, Outlook avtomatik ravishda barcha turdagi bayroqchalar uchun vazifalarning standart eslatma vaqtini ishlatadi. Shunga qaramay, agar siz element turiga qarab belgilangan elementlar uchun turli eslatma vaqtlaridan foydalanmoqchi bo'lsangiz, ushbu maqolada keltirilgan usulga murojaat qilishingiz mumkin.

Outlook element turidan qat'i nazar, barcha bayroqlangan elementlar uchun standart eslatma vaqtini o'rnatish imkonini beradi. Siz "Fayl" menyusiga o'tishingiz va "Options" tugmasini bosishingiz mumkin. Keyin, "Outlook Options" oynasida, quyidagi skrinshotda ko'rsatilganidek, "Vazifalar" yorlig'ida "Standart eslatma vaqti" variantini ko'rishingiz mumkin.

Shunga qaramay, ko'pchilik foydalanuvchilar turli xil belgilangan elementlar uchun turli xil eslatma vaqtlaridan foydalanishga umid qilishadi, masalan, belgilangan pochta xabarlari uchun "9:00" va belgilangan kontaktlar uchun "17:30". Endi, quyida biz usulni tanishtirish uchun ushbu misolga e'tibor qaratamiz.

Har xil turdagi bayroqchalar uchun birlamchi eslatma vaqtini belgilang

1. Boshlash uchun Outlook dasturini ishga tushiring.
2. Keyin Outlook VBA muharririga "" havolasi bilan kiring.Outlook-da VBA kodini qanday ishlatish kerak".
3. Keyingi "Microsoft Visual Basic for Applications" oynasida quyidagi kodni "ThisOutlookSession" loyihasiga nusxalang.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Shundan so'ng, ushbu so'lni faollashtirish uchun Outlook-ni qayta ishga tushiring.
5. Bundan buyon, har safar e-pochta xabarini bildirganingizda, eslatma vaqti bayroq tugash sanasida “10:00” ga o'rnatiladi.
6. Va kontaktni belgilaganingizda, eslatma vaqti bayroq tugash sanasida “17:30” ga o'rnatiladi.

Outlook muammolarini moslashuvchan tarzda hal qiling

Outlook-da har xil muammolarga duch kelishingiz mumkin. Shuning uchun, ularni oldindan hal qilish uchun ba'zi choralarni o'rganishingiz kerak. Masalan, agar Outlook-ingiz tez-tez qayta ishga tushsa, Office-ni ta'mirlash yoki uchinchi tomon qo'shimchalarini o'chirib qo'yish kerak va hokazo. Yoki agar Outlook PST-ingiz buzilgan bo'lsa, avval sinab ko'rishingiz mumkin pochta qutisini tuzatish vositasi. Muvaffaqiyatsiz bo'lganda, siz kuchli tashqi vositaga murojaat qilishni davom ettirishingiz mumkin, masalan DataNumen Outlook Repair.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc mdf tiklash va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com