Outlook VBA orqali ma'lum kiruvchi elektron pochta xabarlaridan o'rnatilgan rasmlarni avtomatik ravishda qanday chiqarish mumkin

Agar siz Outlook-ning ma'lum kiruvchi elektron pochta xabarlaridan o'rnatilgan rasmlarni avtomatik ravishda ajratib olishini va saqlashini istasangiz, ushbu maqolaga murojaat qilishingiz mumkin. Bu erda biz VBA kodi bilan buni qanday amalga oshirishni o'rgatamiz.

Ba'zi foydalanuvchilar tez-tez ma'lum kiruvchi elektron pochta xabarlaridan o'rnatilgan tasvirlarni chiqarib olishlari va ularni ma'lum bir Windows papkasida saqlashlari kerak. Har safar buni qo'lda qilish juda qiyin. Shuning uchun ko'pchilik Outlook-ga buni avtomatik ravishda amalga oshirishga imkon beradigan tez va qulay yondashuvni o'rganishni intiqlik bilan kutmoqda. Endi biz siz bilan bunday usulni baham ko'ramiz.

Muayyan kiruvchi elektron pochta xabarlaridan o'rnatilgan rasmlarni avtomatik chiqarib olish

1. Birinchidan, odatdagidek Outlook dasturini ishga tushiring.
2. Keyin, odatdagidek Outlook VBA muharririni ishga tushiring.Outlook-da VBA kodini qanday ishlatish kerak".
3. Keyinchalik, quyidagi VBA kodini nusxa ko'chiring va "ThisOutlookSession" loyihasiga joylashtiring.

Public WithEvents objInbox As Outlook.Folder
Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Set objInboxItems = objInbox.Items
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.Attachments
    Dim objAttachment As Outlook.Attachment
    Dim strWindowsFolder As String
    Dim i As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Specify the emails as per your needs
       If objMail.Importance = olImportanceHigh Then
          Set objAttachments = objMail.Attachments
 
          'Specify the windows folder
          strWindowsFolder = "E:\" & objMail.Subject & Format(Now, "yymmddhhmmss")
          MkDir (strWindowsFolder)
 
          'Save all embedded images to the folder
          For i = 1 To objAttachments.Count
              Set objAttachment = objAttachments.Item(i)
              If IsEmbedded(objAttachment) = True Then
                 objAttachment.SaveAsFile strWindowsFolder & "\" & objAttachment.FileName
              End If
          Next
      End If
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

4. Shundan so'ng, "Application_Startup" kichik dasturiga o'ting.
5. Nihoyat, ushbu makrosni ishga tushirish uchun "F5" tugmasini bosing.
6. Bundan buyon, har safar Inbox-ga ma'lum bir yangi elektron pochta kelganida, o'rnatilgan tasvirlar quyidagi skrinshotda ko'rsatilganidek, ma'lum bir Windows papkasida saqlanadi.

Doimiy ravishda katta qo'shimchalarni tozalang

Outlook-dagi katta qo'shimchalarni muntazam ravishda tozalash tavsiya etiladi. Bu Outlook faylingizni kerakli hajmda saqlashga qaratilgan. Kattaroq Outlook fayli buzilishga ko'proq moyil bo'ladi. Ma'lumki, PST shikastlanishini yaxshi hal qilish juda qiyin. Ehtimol, avval uni pochta qutisini ta'mirlash vositasi orqali tuzatishga harakat qilasiz. Biroq, ko'p hollarda bu ishlamaydi. Sizning yagona yordamchingiz ixtisoslashgan. PST ta'mirlash asbob, kabi DataNumen Outlook Repair, yoki tegishli professional tiklash xizmatlari.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc mdf tuzatish va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com