Outlook kontaktlaringizdan ma'lum bir domenga ega bo'lgan barcha elektron pochta manzillarini qanday qilib ommaviy olib tashlash mumkin

Ba'zida siz kontaktlaringizdan ma'lum bir domenga ega bo'lgan barcha elektron pochta manzillarini o'chirib tashlashingiz mumkin. Bunday vaziyatda siz buni birma-bir qilishni xohlamasligingiz kerak. Shunday qilib, bu post sizga ancha aqlli usulni o'rgatadi.

Masalan, kompaniya o'z nomini o'zgartiradi. Shu bilan birga, kompaniya domeni ham o'zgartiriladi. Biroq, Outlook-da siz ushbu kompaniyadagi ko'plab kontaktlarni saqladingiz, ularning elektron pochta manzillari eski domenga tegishli. Albatta, bu elektron pochta manzillari endi haqiqiy emas. Shunday qilib, bu holatda, agar siz ushbu elektron pochta manzillarini bir vaqtning o'zida o'chirmoqchi bo'lsangiz, quyidagi usuldan foydalanishingiz mumkin.

Kontaktlardan ma'lum bir domenga ega bo'lgan barcha elektron pochta manzillarini ommaviy ravishda olib tashlang

1. Sifatida uchuntart, Outlook VBA muharririga yorliq yorlig'i - "Alt + F11" orqali kiring.
2. Keyin, yangi oynada, quyidagi VBA kodini bo'sh modulga joylashtiring.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Shundan so'ng, kursorni "BatchRemoveAllEmailAddressesInSpecificDomain" pastki dasturiga qo'ying.
4. Nihoyat, ushbu makrosni ishga tushirish uchun "F5" tugmachasini bosing.
5. Keyinchalik, qalqib chiquvchi dialog oynasiga maxsus domenni kiriting.
6. "OK" tugmasini bosgandan so'ng makro ishga tushadi.
7. U tugagach, natijalar haqida xabar olasiz.
8. Endi siz kontaktlarni tekshirishingiz mumkin. Muayyan domenga ega bo'lgan barcha elektron pochta manzillari yo'qolgan bo'lishi kerak.

Outlook faylingizni saqlang

Outlook bilan bog'liq xavflar ortib borayotganligi sababli, qimmatli Outlook ma'lumotlarini himoya qilish tobora qiyinlashmoqda. Misol uchun, siz nafaqat ma'lumotlarni muntazam zahiralashda davom etishingiz kerak, balki operatsiyalaringizga ham ehtiyot bo'lishingiz kerak. Noma'lum jo'natuvchilardan kelgan har qanday elektron pochta xabarlariga osongina ishonish oqilona emas. Aks holda, agar u virusga ega bo'lsa, Outlook faylingiz zararlangan bo'ladi. O'sha paytda siz harakat qilishingiz kerak Outlook-ni ta'mirlash kabi ajoyib tuzatish vositasi orqali DataNumen Outlook Repair.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc tiklash Sql Server va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com