Outlook-da bitta jildning barcha pastki jildlaridan boshqa papkaga elektron pochta xabarlarini qanday qilib ommaviy ko'chirish mumkin

Ehtimol, sizda ko'plab pastki papkalar joylashgan papkangiz bor. Agar siz ulardagi elektron pochta xabarlarini qayta tashkil qilmoqchi bo'lsangiz, masalan, barcha xatlarni ushbu pastki jildlardan ma'lum bir jildga tezda ko'chirish, ushbu maqolada ulashilgan usuldan foydalanishingiz mumkin.

Ba'zi sabablarga ko'ra, elektron pochta xabarlarini qayta tasniflashni xohlaysiz, shuning uchun bu pastki jildlar endi foydali bo'lmasligi uchun, ba'zi sabablarga ko'ra, elektron pochta xabarlarini bitta jildning barcha pastki jildlaridan boshqa papkaga ko'chirishingiz kerak bo'lishi mumkin. Bunday holda, ushbu pastki papkalarni birma-bir qayta ishlash juda qiyin. Shuning uchun, bu erda biz sizni boshqa yo'l bilan tanishtiramiz.

Elektron pochta xabarlarini bitta jildning barcha pastki papkalaridan boshqa jildga ommaviy ko‘chirish

1. Eng boshidanoq, Outlook dasturingizni ishga tushiring.
2. Keyin, asosiy Outlook ekranida sizni VBA muharririga olib keladigan "Alt + F11" tugmachalarini bosing.
3. Keyin, yangi "Microsoft Visual Basic for Applications" oynasida ishlatilmaydigan modulni ochishingiz kerak.
4. Keyinchalik, ushbu modulga quyidagi VBA kodini nusxa ko'chiring va joylashtiring.

Dim objTargetFolder As Outlook.folder

Sub BatchMoveEmailsFromSubfoldersToAnotherFolder()
    Dim objSourceFolder As Outlook.folder
    Dim objFolder As Outlook.folder
  
    'Get the source folder whose subfolders to be processed
    Set objSourceFolder = Application.Session.PickFolder
 
    If Not (objSourceFolder Is Nothing) And objSourceFolder.DefaultItemType = olMailItem Then
       If objSourceFolder.folders.count > 0 Then
          'Select a target folder
          Set objTargetFolder = Application.Session.PickFolder
          If Not (objTargetFolder Is Nothing) Then
             For Each objFolder In objSourceFolder.folders
                 Call ProcessFolders(objFolder)
             Next
             MsgBox "Move Completed!", vbExclamation
          End If
       Else
          MsgBox "No subfolders!", vbExclamation
       End If
    End If
End Sub

Sub ProcessFolders(ByVal objFolder As Outlook.folder)
    Dim i As Long
    Dim objSubfolder As Outlook.folder
 
    For i = objFolder.Items.count To 1 Step -1
        'Move emails to the target folder
        If objFolder.Items(i).Class = olMail Then
           objFolder.Items(i).Move objTargetFolder
        End If
    Next
 
    'Process subfolders recursively
    If objFolder.folders.count > 0 Then
       For Each objSubfolder In objFolder.folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Shundan so'ng siz ushbu makrosni ishga tushirishingiz mumkin.

• Avval ushbu so'l oynada "F5" tugmachasini bosing.
• Keyin, sizdan pastki papkalari qayta ishlanadigan manba papkasini tanlashingiz talab qilinadi.
• Shundan so'ng, siz elektron pochta xabarlarini ko'chirmoqchi bo'lgan maqsad papkani belgilashingiz kerak.
• Keyinchalik, ushbu makro ishlay boshlaydi. U tugallangandan so'ng, siz "Bajarildi" degan xabarni olasiz.
• Oxir-oqibat, siz maqsadli papkaga kirishingiz mumkin. Siz manba papkasidagi barcha pastki papkalarning elektron pochta xabarlari u yerda ekanligini ko'rasiz.

Buzilgan Outlook ma'lumotlarini tiklash

Boshqa elektron pochta mijozlari kabi ko'plab xususiyatlar bilan maqtansa ham, Outlook ham korruptsiyadan qochib qutula olmaydi. Ko'proq va ko'proq ma'lumotlar saqlanganligi sababli, Outlook xatolar va zararlarga tobora ko'proq moyil bo'ladi. Shunday qilib, siz kuchli ta'mirlash vositasini qo'lingizda saqlashingiz kerak, masalan DataNumen Outlook Repair. Bu, ayniqsa, mo'ljallangan Outlook-ni tuzatish masalalar. Shunday qilib, u shikastlangan Outlook faylini osongina skanerlashi va tiklashi mumkin.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc mdf tiklash va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datKanumen.com