Suhbatdagi barcha elektron pochta xabarlarini Outlook VBA orqali matnli fayllar sifatida qanday ommaviy eksport qilish mumkin

Ba'zan siz ma'lum bir suhbatdagi barcha elektron pochta xabarlarini to'plashni va keyin ularni matnli fayllar sifatida mahalliy papkaga eksport qilishni xohlashingiz mumkin. Ushbu maqola sizga uni tezda qanday qilib olishni o'rgatadi.

Ba'zi sabablarga ko'ra, ma'lum bir suhbatdagi barcha elektron pochta xabarlarini mahalliy diskingizga eksport qilishingiz kerak bo'lishi mumkin. Agar siz buni qo'lda qilsangiz, ya'ni birma-bir topib, saqlasangiz, bu zerikarli va mashaqqatli ish bo'ladi. Shuning uchun, siz boshqa tezroq usulni izlaganingiz ma'qul, masalan, quyidagi. U ter to'kmasdan olish uchun VBA kodining bir qismidan foydalanadi.

Suhbatdagi barcha xatlarni matnli fayllar sifatida ommaviy eksport qilish

1. Eng boshida Outlook ilovasini ishga tushiring.
2. Keyin Outlook VBA muharririga kirish uchun "Alt + F11" tugmachalarini bosing.
3. Keyinchalik, yangi oynada siz ishlatilmaydigan modulni ochishingiz yoki to'g'ridan-to'g'ri yangi modulni kiritishingiz kerak.
4. Keyinchalik, ushbu modulga quyidagi VBA kodlarini nusxalashingiz va joylashtirishingiz kerak.

Public strFilePath, strFileName As String

Sub ExportMailsInConversationAsTXT()
    Dim objSelectedMail As Outlook.MailItem
    Dim objConversation As Outlook.Conversation
    Dim objMail As Outlook.MailItem

    Set objSelectedMail = ActiveExplorer.Selection.Item(1)
    Set objConversation = objSelectedMail.GetConversation
 
    If Not (objConversation Is Nothing) Then
       'Get all root items in this conversation
       For Each objMail In objConversation.GetRootItems
 
          strFileName = objMail.Subject
 
          'Remove the unsupported characters in email subject
          strFileName = Replace(strFileName, "/", " ")
          strFileName = Replace(strFileName, "\", " ")
          strFileName = Replace(strFileName, ":", "")
          strFileName = Replace(strFileName, "?", " ")
          strFileName = Replace(strFileName, Chr(34), " ")

          strFileName = Format(objMail.ReceivedTime, "YYYY-MM-DD") & "_" & strFileName & ".txt"
 
         'Export as Text files
         'Change "E:\" to other local folder path as per your needs
         strFilePath = "E:\" & strFileName
         objMail.SaveAs strFilePath, OLTXT

         'Process all children as well
         Call ProcessChildren(objMail, objConversation)
      Next
   End If

   MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessChildren(objCurMail As Outlook.MailItem, objCurConversation As Outlook.Conversation)
    Dim objItems As Outlook.SimpleItems
    Dim objItem As Outlook.MailItem
 
    Set objItems = objCurConversation.GetChildren(objCurMail)

    If objItems.Count > 0 Then
       For Each objItem In objItems
 
           strFileName = objItem.Subject
 
           strFileName = Replace(strFileName, "/", " ")
           strFileName = Replace(strFileName, "\", " ")
           strFileName = Replace(strFileName, ":", "")
           strFileName = Replace(strFileName, "?", " ")
           strFileName = Replace(strFileName, Chr(34), " ")
 
           strFileName = Format(objItem.ReceivedTime, "yyyy-mm-dd") & "_" & strFileName & ".txt"
 
           strFilePath = "E:\" & strFileName
           objItem.SaveAs strFilePath, OLTXT
 
           'Process all children recursively
           Call ProcessChildren(objItem, objCurConversation)
       Next
    End If
End Sub

5. Shundan so'ng siz odatdagidek tez kirish asboblar paneliga yangi VBA loyihasini qo'shishingiz mumkin.
6. Keyinchalik Outlook makro xavfsizlik darajasini past darajaga keltiring.
7. Nihoyat, siz sinab ko'rishingiz mumkin.

• Birinchidan, elektron pochta manzilini tanlang.
• Keyin Tez kirish asboblar panelidagi yangi makros tugmasini bosing.
• "Bajarildi" xabarini olganingizda, siz "TXT" formatidagi elektron pochta xabarlarini ko'radigan oldindan belgilangan mahalliy papkani ochishingiz mumkin.

Korruptsiyadan keyin PST ma'lumotlarini tiklash bo'yicha maslahatlar

Ko'pincha, Outlook-da siz turli xil Outlook xatolariga duch kelishingiz mumkin, ularning ba'zilari jiddiy bo'lib, ular to'g'ridan-to'g'ri PST buzilishiga olib keladi. O'sha paytda siz choralar ko'rishingiz kerak PST-ni ta'mirlash qimmatli ma'lumotlaringizni topish uchun fayl. Bunday holda, siz faqat obro'li va yaxshi tasdiqlangan vositaga murojaat qilishingiz mumkin, masalan DataNumen Outlook Repair.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc tiklash sql server va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com