Outlook-da elektron pochta qayd etilganda yangi uchrashuvni qanday avtomatik yaratish mumkin

Ba'zi odamlar elektron pochta xabarini bildirganda avtomatik ravishda yoki tezda yangi Outlook uchrashuvini yaratishni xohlashadi. Ushbu maqola uni Outlook VBA bilan amalga oshirish uchun yondashuvni taqdim etadi.

Ba'zan men uchrashuv yoki uchrashuv haqida eslatib o'tadigan elektron pochta xabarini olishim mumkin. Ammo bu Outlook-dagi umumiy yig'ilish elementi o'rniga shunchaki elektron pochta. Bunday holda, men Outlook taqvimimda qo'lda yangi uchrashuv yaratishim kerak. Bu biroz muammoli. Shunday qilib, Outlook avtomatik ravishda yangi uchrashuv yaratishini xohlayman. Shunga qaramay, Outlook elektron pochta xabarini bildirganimizda avtomatik ravishda yangi uchrashuv yaratishimiz uchun mahalliy yordamga ega emas. Shuning uchun, bunga erishish uchun men Outlook VBA-dan foydalanishni tanlayman. Mana batafsil VBA kodlari va qadamlari.

Elektron pochta qayd etilganda avtomatik yangi uchrashuv yaratish

1. Birinchidan, "Dasturchi" yorlig'iga o'ting va "Kod" guruhidagi "Visual Basic" tugmasini bosing.
2. Keyin yangi "Microsoft Visual Basic for Applications" oynasida ushbu loyihani ochish uchun "ThisOutlookSession" tugmasini ikki marta bosishingiz kerak.
3. Va keyin quyidagi VBA kodlarini nusxa ko'chiring va unga joylashtiring.

Public WithEvents olItems As Outlook.Items

Private Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub olItems_ItemChange(ByVal Item As Object)
    Dim oAppt As AppointmentItem
    Dim strMsg As String
    Dim nRes As Integer
 
    On Error Resume Next
 
    If TypeName(Item) = "MailItem" And Item.IsMarkedAsTask = True Then
       strMsg = "Do you want to create a new appointment"
       nRes = MsgBox(strMsg, vbYesNo + vbQuestion, "Confirm Creating Appointment")
       If nRes = vbYes Then
          Set oAppt = Application.CreateItem(olAppointmentItem)
          With oAppt
               .Subject = "New Appt: " & Item.Subject
               .Location = InputBox("Enter the Location, please.")
               'Type the concrete time, such as "12/29/2015 15:30"
               .Start = InputBox("Enter a specific time (format: MM/DD/YYYY hh:mm), please.")
               .Duration = 120
               .Body = "New Appointment: " & vbCrLf & vbCrLf & Item.Body
               .Attachments.Add Item
               .ReminderSet = True
               .ReminderMinutesBeforeStart = 30
               'Use ".Save" to directly save the new appointment
               .Display
          End With
       End If
 
      'To clear the flag on the email
      'If you want to keep email flagged, remove the following 4 lines
       With Item
            .ClearTaskFlag
            .Save
       End With
    End If
End Sub

4. Keyinchalik, yangi sertifikat yaratish va joriy "ThisOutlookSession" loyihasini imzolash uchun "VBA loyihalari uchun raqamli sertifikat" dan foydalanishingiz kerak.
5. Shundan so'ng siz "Visual Basic" oynasidan chiqishingiz va makro sozlamalarini faqat raqamli imzolangan makroslarga ruxsat berish uchun o'zgartirishingiz mumkin.
6. Oxir-oqibat, siz sinab ko'rishingiz mumkin.

• Birinchidan, elektron pochtani kiriting va "Bayroq" belgisini bosing. Siz quyidagi skrinshot kabi so'rovni olasiz:
• "Ha" ni tanlaganingizdan so'ng siz joylashuvni belgilashingiz va "OK" tugmasini bosishingiz kerak bo'ladi.
• Keyin uchrashuv vaqtini belgilashingiz kerak.
• Nihoyat, "OK" tugmasini bosgandan so'ng, quyidagi rasmda ko'rsatilgan yangi uchrashuv ochiladi:

Eslatmalar:

1. Ushbu VBA kodlarida eslatma sukut bo'yicha 30 daqiqaga o'rnatiladi. Siz uni o'zingizning xohishingiz bilan kodlarda o'zgartirishingiz mumkin.
2. Kodlar uchrashuvning davomiyligini 120 daqiqa, ya'ni 2 soat qilib belgilab qo'ydi. ".Duration = 120" qatorini ehtiyojlaringizga qarab o'zgartirishingiz mumkin.
3. Agar siz aniq vaqtni belgilamagan bo'lsangiz, yangi uchrashuv sukut bo'yicha joriy sana va vaqtga o'rnatiladi.
4. Uchrashuvni to'g'ridan-to'g'ri saqlash uchun ".Saqlash" qatorini qo'shishingiz mumkin.

Outlook muammolarini yo'q qiling

Ma'lumki, Outlook turli xil muammolarga duch kelishi mumkin. Eng yomon vaziyat Outlook korruptsiyalari bo'lishi kerak. Agar Outlook faylingiz buzilgan bo'lsa va qo'lingizda zaxira nusxasi bo'lsa, uni osongina tiklashingiz mumkin zararlangan Outlook ma'lumotlari zaxira nusxalaridan. Ammo zaxirangiz bo'lmasa, buzilgan Outlook faylini tuzatishingiz kerak bo'ladi. Bunday holda siz o'rnatilgan Scapst.exe ta'mirlash vositasidan foydalanishingiz yoki tajribaliroq vositaga murojaat qilishingiz mumkin, masalan. DataNumen Outlook Repair.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc ta'mirlash SQL Server mdf ma'lumotlar bazasi muammosi va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com