VBA orqali bir nechta Word hujjatlarini tezda birlashtirishning 2 usuli

Ushbu maqolada biz VBA orqali bir nechta Word hujjatlarini tezda birlashtirishning 2 usulini siz bilan baham ko'rishdan mamnunmiz.

Word-da foydalanuvchiga bir nechta hujjatlarni birlashtirish yoki birlashtirishga yordam beradigan standart o'rnatilgan xususiyat mavjud. Tafsilotlar ushbu maqolada tasvirlangan: Bir nechta Word hujjatlarini qanday qilib birlashtirish va birlashtirish

Ushbu usul bilan siz bir necha marta bosishingiz kerak va keyingi hujjatning mazmuni har doim oldingi hujjatdan keyin keladi. Shuning uchun biz sizga buni qilishning tezroq usullarini taklif qilmoqchimiz.

1-usul: Tanlangan hujjatlarni bittaga birlashtiring

1. Avvalo, yangi bo'sh hujjat yarating.
2. “Alt+ F11” tugmachalarini bosib Word-da VBA muharririni ishga tushiring.
3. Keyin "Oddiy" tugmasini bosing.
4. Keyin "Qo'shish" tugmasini bosing.
5. Va "Modul" ni tanlang.
6. Tahrirlash maydonini ochish uchun yangi modulni ikki marta bosing.
7. U erga quyidagi makroni joylashtiring:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Keyin "Ishga tushirish" tugmasini bosing yoki "F5" tugmasini bosing.
9. Endi "Browse" oynasida "Ctrl" tugmasini bosib bir nechta fayllarni tanlang va "OK" tugmasini bosing.
10. Keyin tanlangan fayllardagi barcha tarkib yangi hujjatda birlashtiriladi, har bir hujjatning matnlari yangi sahifadan boshlanadi.

Eslatma:

Yuqorida aytib o'tganimizdek, ushbu makros har bir hujjatning matnlarini yangi sahifaga joylashtiradi. Ammo agar siz ularni birin-ketin bo'lishi kerak bo'lsa, siz makrodagi ba'zi kod satrlarini o'zgartirishingiz mumkin. Shunchaki “If nEachSelectedFile < nTotalFiles Keyin” qatorini toping, uni va keyingi olti qatorni ham o‘chirib tashlang.

2-usul: Jilddagi barcha hujjatlarni bittaga birlashtiring

Agar sizda birlashtiriladigan fayllar papkasi bo'lsa, bu makros juda yaxshi ishlaydi.

1. Boshlash uchun, 1-usulda tasvirlanganidek, makrosni o'rnating va ishga tushiring.
2. Keyin makroni shu bilan almashtiring:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. "Ishga tushirish" tugmasini bosish orqali makrosni ishga tushiring.
4. Keyin ochilgan "Browse" oynasini ko'rasiz. Barcha hujjatlar saqlanadigan jildni tanlang. Va "OK" tugmasini bosing.

Xuddi shunday, har bir hujjatning matnlari yangi sahifadan boshlanadi. Ularni bir-biriga yopishtirish uchun “.InsertBreak Type:=wdPageBreak” kod qatorini toping va oʻchiring.

Word hujjatingizni to'g'ri himoya qiling

Word hujjatlarini himoya qilishning eng yaxshi usullaridan biri ularni muntazam ravishda zaxiralashdir. Qo'lda zaxira nusxalari bilan siz hech qachon ma'lumotlar yo'qolishidan qo'rqmaysiz. Bundan tashqari, vositani olish ham tavsiya etiladi docx-ni ta'mirlash agar ulardan birortasi shikastlangan bo'lsa.

Muallif kirish:

Vera Chen - ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc shikastlangan Excel va pdf dasturiy mahsulotlarni ta'mirlash. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com