Outlook-da elektron pochta manzili bo'lmagan barcha kontaktlarni to'plamda o'chirishning 2 usuli

Agar Outlook-da ba'zi kontaktlarning elektron pochta manzili yo'qligini aniqlasangiz, barcha kontaktlarni o'chirish uchun har bir Kontakt papkasini qayta ishlashingiz mumkin. Ushbu post siz bilan 2 ta usulni baham ko'radi.

Ehtimol, sizning Outlook-da ko'plab kontaktlaringiz bor va ularning ba'zilarida elektron pochta manzili yo'q. Agar ular endi foydali emas deb hisoblasangiz, elektron pochta manzili bo'lmagan barcha kontaktlarni o'chirishga umid qilishingiz kerak. Standart usulda siz ularni topish uchun "Instant Search" dan foydalanishingiz mumkin va keyin ularni quyidagi 1-usul kabi qo'lda o'chirishingiz mumkin. Shunga qaramay, bu biroz zerikarli. Shuning uchun, 2-usulda biz sizga boshqa samaraliroq usulni o'rgatamiz.

1-usul: Elektron pochta manzili bo'lmagan kontaktlarni topgandan keyin qo'lda o'chirish

1. Boshlash uchun "Kontaktlar" paneliga kirish uchun "Ctrl + 3" tugmalarini bosing.
2. Keyin, qidiruv maydoniga bosing.
3. Keyin paydo bo'ladigan "Qidiruv" tasmasida "Barcha kontaktlar" ni bosing.
4. Keyinchalik, "Manzil bor" > "Elektron pochta manzili bor" ni bosing.
5. Shundan so'ng, qidiruv maydoniga "EMQ elektron pochta manzillari:=[]" mezoni qo'shiladi. "YO'Q" ni olib tashlashingiz kerak.
6. Keyinchalik, elektron pochta manzili bo'lmagan barcha kontaktlar ro'yxatga olinadi.
7. Endi siz qidiruv natijalarida kontaktlarni qo'lda tanlashingiz kerak, chunki kontakt guruhlaringiz ham ro'yxatda bo'lishi kerak.
8. Nihoyat, barcha tanlangan kontaktlarni o'chirish uchun "Del" tugmachasini bosing.

2-usul: VBA yordamida barcha kontaktlarni elektron pochta manzilisiz o'chirish

1. Avval Outlook-da VBA muharririni ishga tushirish uchun “Alt + F11” tugmachalarini bosing.
2. Yangi ekranda quyidagi VBA kodini modulga nusxalang.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Keyinchalik, "BatchDeleteAllContactsWithoutEmailAddress" pastki dasturini bosing.
4. Oxir-oqibat, ushbu makrosni ishga tushirish uchun "F5" tugmasini bosing.
5. U tugagach, siz quyidagi rasmdagi kabi natijalar haqida xabar olasiz.
6. Elektron pochta manzili bo'lmagan barcha kontaktlar "O'chirilgan elementlar" jildiga ko'chirildi.

Barcha mumkin bo'lgan xavflardan uzoqroq turing

Outlook viruslar, foydalanuvchi xatolari, dasturiy ta'minotdagi nosozliklar, shuningdek apparatdagi nosozliklar kabi turli omillar tufayli buzilishi mumkin. Siz Outlookga zarar yetkazishni istamasligingiz kerak, shuning uchun barcha mumkin bo'lgan xavflarni qo'lingizda ushlab turishingiz kerak. Masalan, kompyuteringizga kuchli antivirus dasturini o'rnatishingiz kerak. Bundan tashqari, siz muntazam ravishda Outlook ma'lumotlarini zaxiralashingiz kerak. Va nihoyat, eng muhimi, siz mustahkam va ishonchli ta'mirlash vositasini tayyorlashingiz kerak, masalan DataNumen Outlook Repair. Bu sizni tuzatishi mumkin buzilgan PST osonlik bilan fayl.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc SQL Server korruptsiya va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com