Birden Çok Klasördeki Öğeleri Outlook'ta Yinelemeler Olmadan Hızlı Bir Şekilde Birleştirme

Birden çok Outlook klasöründeki tüm öğeleri birleştirmek ve yinelenmemesini sağlamak istiyorsanız, bu makalede açıklanan yöntemi kullanabilirsiniz. Bir mantar gibi başarmanıza yardımcı olmak için VBA kodunu kullanıyor.

Bazen, birkaç Outlook Kişileri klasörünün tüm kişilerini birleştirmek gibi, birkaç Outlook klasöründeki öğeleri birleştirmek isteyebilirsiniz. Bu durumda, bu klasörler arasında yinelenen bazı kişiler varsa, birleştirme sırasında yinelenenlerin otomatik olarak kaldırılabileceğini ummalısınız. Bu durumda, zahmetsizce gerçekleştirmek için aşağıdaki VBA kodunu kullanabilirsiniz.

Birden Çok Klasördeki Öğeleri Yinelemeler Olmadan Birleştirin

1. İçintart ile Outlook uygulamanızı başlatın.
2. Ardından, Outlook ana ekranında “Alt + F11” tuşlarına basarak Outlook VBA düzenleyicisine erişmeniz gerekir.
3. Ardından, “Uygulamalar için Microsoft Visual Basic” penceresinde kullanılmayan bir modülü açmanız gerekir.
4. Daha sonra aşağıdaki VBA kodunu bu modüle kopyalamalısınız.

'Here we take "merging two folders" as an example
Sub MergeOutlookFolders_WithoutDuplicates()
    Dim objSourceFolder As Outlook.Folder
    Dim objTargetFolder As Outlook.Folder
    Dim i, n, x As Long
    Dim objItem As Object
    Dim objDictionary As Object
    Dim strKey As String
 
    Set objSourceFolder = Application.Session.PickFolder
    Set objTargetFolder = Application.Session.PickFolder

    If objSourceFolder.DefaultItemType <> objTargetFolder.DefaultItemType Then
       MsgBox "Error: The two folders are not in same type!", vbExclamation + vbOKOnly
    Else
       'Merge the two folders
       For i = objSourceFolder.Items.count To 1 Step -1
           Set objItem = objSourceFolder.Items.Item(i)
           objItem.Move objTargetFolder
       Next i
 
       Set objDictionary = CreateObject("scripting.dictionary")
 
       'Remove the duplicates
       x = 0
       For n = objTargetFolder.Items.count To 1 Step -1
           Set objItem = objTargetFolder.Items.Item(n)
 
           Select Case objItem.Class
                  Case olMail
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  Case olAppointment
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  Case olContact
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  Case olTask
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
              x = x + 1
           Else
              objDictionary.Add strKey, True
           End If
      Next n
 
      'Prompt you of the count of removed duplicates
      If x <> 0 Then
         MsgBox x & " duplicates removed when merging!", vbInformation + vbOKOnly
      End If
    End If
End Sub

5. Daha sonra, makronun etkinleştirildiğinden emin olarak Outlook makro ayarlarınızı kontrol etmeniz gerekir.
6. Sonunda bir deneyebilirsin.

• İlk olarak, yeni modül penceresine geri dönün.
• Daha sonra bu makroyu tetiklemek için F5 tuş düğmesine basın.
• Ardından birleştirilecek iki klasörü seçmeniz gerekir. Birincisi kaynak, ikincisi ise tarbirini almak.
• Bundan sonra Outlook, kaynak klasördeki tüm öğeleri tarbirini almak. Ayrıca, bu arada kopyalar otomatik olarak kaldırılacaktır.
• Son olarak, aşağıdaki ekran görüntüsü gibi, kaldırılan kopyaların sayısını soran bir mesaj alabilirsiniz:

Ufak Hatalar Büyük Kazalara Neden Olabilir

Çok sayıda mükemmel işlevle dolu olmasına rağmen, Outlook hala hatalara ve bozulmaya karşı hassastır. Belki de çeşitli Outlook sorunlarıyla karşılaştınız. Birçok kullanıcı rastgele hataları görmezden gelme eğilimindedir. Ancak, Outlook dosyasını tehlikeye atacak ciddi Outlook çökmelerini tetikleyen küçük bir hatadır. Bu nedenle, herhangi bir küçük hatayı göz ardı etmemelisiniz. Bunun yerine, onları mümkün olan en kısa sürede ortadan kaldırmalısınız. Ayrıca, bir daire tutsan iyi olur PST onarımı araç, örneğin DataNumen Outlook Repair. Yüksek kurtarma oranı sayesinde, bu yardımcı program emsallerine omuz verdi.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. bozuk sql ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com