Oylama İstatistiklerini Outlook E-postasından Excel Çalışma Sayfasına Hızlıca Dışa Aktarma

Oy verme butonları içeren bir e-posta gönderdiyseniz, alıcılar size yanıtlarını gönderdikten sonra, oylama istatistiklerini sayıp bir Excel çalışma sayfasına aktarmak isteyebilirsiniz. Bu yazıda, bunu hızlı bir şekilde nasıl yapacağınızı öğreteceğiz.

Outlook o kadar güçlü ki, bir "Oylama" özelliği bile sunuyor. Bir önceki yazım “Oylama için MS Outlook'un Becerikli Kullanımı"Etkin bir şekilde nasıl kullanılacağını öğrettik. Ayrıca, çoğu zaman, oy verdikten sonra, istatistikleri yazdırmak gibi bazı nedenlerle oy istatistiklerini bir Excel çalışma sayfasına aktarabilirsiniz. Ancak Outlook bunu varsayılan olarak desteklemiyor. Bu nedenle, aşağıda bunu nasıl gerçekleştireceğinizi öğreteceğiz."

Bir E-postadaki Oylama İstatistiklerini Excel Çalışma Sayfasına Aktarın

1. En başta, Outlook uygulamanızı başlatın.
2. Ardından, ana Outlook penceresindeki “Alt + F11” tuşlarına basmalısınız.
3. Ardından, “Microsoft Visual Basic for Applications” penceresinde “Microsoft Excel Nesne Kitaplığı”nı etkinleştirmelisiniz. “Araçlar” > “Referans” seçeneğine tıklayın. Açılan iletişim kutusunda, “Microsoft Excel Nesne Kitaplığı”nın önündeki onay kutusunu işaretleyin ve son olarak “Tamam” düğmesine tıklayın.
4. Bundan sonra, yeni bir modül ekleyebilir veya kullanılmayan bir modülü açabilirsiniz.
5. Ardından, aşağıdaki VBA kodlarını kopyalayıp bu modüle yapıştırın.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Bundan sonra, kolay erişim için, yeni makroyu Hızlı Erişim Araç Çubuğuna ekleseniz iyi olur.
6. Sonunda, bir deneyebilirsin.

• Öncelikle, oylama düğmeleri içeren bir kaynak e-posta seçin.
• Ardından, Hızlı Erişim Araç Çubuğundaki makro düğmesini tıklayın.
• Bu makronun çalışması tamamlandıktan sonra, içinde yeni bir Excel çalışma kitabı göreceğiniz önceden tanımlanmış yerel klasöre göz atabilirsiniz.
• Bu Excel çalışma kitabını açın. Şimdi, aşağıdaki resimde gösterilen oylama istatistiklerini göreceksiniz:

Hiç Kimse Outlook Hatalarını Tamamen Önleyemez

Outlook çeşitli yeteneklerle donatılmış olarak gelse de, Outlook hatalarından kaçınmamıza yardımcı olacak böyle bir özellik yoktur. Her türlü faktör Outlook hatalarına neden olabilir. Örneğin, Outlook'tan sık sık yanlış bir şekilde çıkarsanız, büyük olasılıkla acı çekeceksiniz. PST bozulması. Böyle bir senaryoda, PST dosyanızı kurtarmak için bazı güçlü araçlar kullanmaktan başka seçeneğiniz yoktur. DataNumen Outlook Repair. İyileşme oranı yüksek olduğu için çok övgü aldı.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. bozuk mdf ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com