Her Renk Kategorisinde Outlook Randevularında Harcanan Toplam Süreyi Hızlı Bir Şekilde Dışa Aktarma

Her bir renk kategorisindeki randevular için harcadığınız toplam süre hakkında bir rapor oluşturmak isterseniz, bu makaledeki yöntemi kullanabilirsiniz. Manuel olarak saymaya gerek kalmadan bunu hızlı bir şekilde gerçekleştirmenize yardımcı olabilir.

Birçok kullanıcı etkinliklerinin çoğunu Outlook takvimine kaydetmeye alışkındır. Ayrıca, bunları daha kolay yönetmek ve ayırt etmek için her birine kategori atarlar. Bu durumda, bazı kullanıcılar her renk kategorisindeki takvim öğelerinde geçirilen toplam süreyi gösteren bir rapor oluşturmak isteyebilir. Şüphesiz ki, bunu manuel olarak saymak ve girmek zahmetlidir. Bu nedenle, burada bu görevi tek bir tıklamayla gerçekleştirebilecek bir yöntem paylaşacağız.

Her Renk Kategorisindeki Randevularda Harcanan Toplam Süreyi Dışa Aktar

1. İlk etapta, Outlook uygulamanızı başlatın.
2. Ardından, Outlook penceresine girdikten sonra “Alt + F11” tuş düğmelerine dokunabilirsiniz.
3. Daha sonra, “Uygulamalar için Microsoft Visual Basic” penceresine erişeceksiniz.
4. Ardından, “Microsoft Excel Nesne Kitaplığı”nı etkinleştirmeniz gerekecektir. Bunu yapmak için “Araçlar” > “Referans” seçeneğine tıklayabilirsiniz.
5. Ardından, kullanılmayan bir modülü bulup açmalısınız.
6. Daha sonra aşağıdaki VBA kodunu bu modüle kopyalamanız gerekmektedir.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Son olarak, araç çubuğundaki “Çalıştır” simgesine tıklayarak veya “F5” tuşuna basarak bu makroyu tetikleyebilirsiniz.
8. Ardından, belirli bir takvim seçmeniz istenecektir.
9. Seçip “Tamam” düğmesine bastıktan sonra, makro çalışmaya devam edecektir. Tamamlandıktan sonra, arka planda görüntülenen yeni bir Excel dosyası olacaktır.
10. Erişebilirsin. Aşağıdaki ekran görüntüsü gibi görünecektir:

Görünümünüzle İlgili Potansiyel Tehditlere Dikkat Edin

Outlook kullanıcıları, bilinmeyen e-posta ekleri, katıştırılmış bağlantılar ve insan hataları dahil olmak üzere tüm potansiyel risklere dikkat etmelidir. Aksi takdirde, Outlook'unuz her an bozulabilir. Ayrıca, düzenli Outlook veri yedeklemeleri yapmak ve özel bir onarım aracı bulundurmak da bir zorunluluktur. DataNumen Outlook Repair En çok tavsiye edilen onarım araçlarından biridir. Outlook'u onar problemler bir anda.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. hasarlı mdf ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com