Bir PST Dosyasındaki Tüm Klasörlerin Boyut Bilgilerini Hızlı Bir Şekilde Excel Dosyasına Dışa Aktarma

Bir PST dosyasındaki her klasörün boyut bilgisini kontrol etmek istiyorsanız, bu makalede açıklanan yöntemi kullanabilirsiniz. Bir PST dosyasındaki tüm klasörlerin boyut bilgilerini hızlı bir şekilde bir Excel dosyasına aktaracaktır.

PST dosyanız çok büyük olduğunda, her bir klasörün boyutunu kontrol etmek isteyebilirsiniz. Hangilerinin daha büyük olduğunu kolayca anlamanıza ve boyuta göre uygun arşivleme yapmanıza yardımcı olur. Genel olarak, klasör boyutunu kontrol etmek için bir klasöre sağ tıklayıp "Özellikler"i seçebilirsiniz. Yeni açılır iletişim kutusunda, “Klasör Boyutu” düğmesine tıklayabilirsiniz. Ancak çok sayıda klasör oluşturduysanız, boyut bilgilerini tek tek manuel olarak kontrol etmek oldukça zahmetlidir. Bu nedenle, bir PST dosyasındaki tüm klasörlerin boyut bilgilerini toplu olarak almak istiyorsanız, aşağıdaki VBA kodunu kullanabilirsiniz. Tüm klasör adlarını ve boyut bilgilerini tek seferde bir Excel dosyasına aktaracaktır.

Bir PST Dosyasındaki Tüm Klasörlerin Boyut Bilgilerini Bir Excel Dosyasına Aktarın

1. Öncelikle Outlook uygulamanızı başlatın.
2. Ardından “Geliştirici” sekmesine geçin ve “Visual Basic” butonuna tıklayın veya “Alt + F11” tuşlarına basarak VBA editörüne giriş yapın.
3. Sonraki "Uygulamalar için Microsoft Visual Basic" penceresinde, kullanılmayan bir modülü açın.
4. Ardından, aşağıdaki VBA kodlarını kopyalayıp bu modüle yapıştırın.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Bundan sonra, Outlook makro güvenlik düzeyinizi düşük olarak ayarlamanız gerekir.
6. Sonunda, bir deneyebilirsin.

• Geçerli makro penceresinde F5 tuş düğmesine basın.
• Ardından, aşağıdaki görüntü gibi bir PST dosyası seçmeniz istenecektir:
• Bir kaynak dosya seçtikten sonra Outlook, boyut bilgilerini Excel'e aktarmaya başlayacaktır.
• Makro bittikten sonra aşağıdaki ekran görüntüsü gibi bir mesaj alırsınız.
• Son olarak, Excel dosyasını önceden tanımlanmış yerel klasörde bulabileceksiniz. Excel dosyası aşağıdaki gibi görünecektir:

Sık PST Hatalarıyla Başa Çıkın

Outlook hatalara eğilimli olduğundan, Outlook'unuzda şimdiye kadar pek çok sorun yaşamış olabilirsiniz. Sinir bozucu PST sorunlarıyla daha iyi ve daha esnek bir şekilde başa çıkmak için, yakınlarda deneyimli ve saygın bir düzeltme aracı bulundurmanız önerilir. DataNumen Outlook Repair. Yapabiliyor PST'yi düzelt rüzgar gibi sorunlar.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. SQL Server kurtarma ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com