“Sık Kullanılanlar” Bölümündeki Tüm Outlook Klasörlerini ve Öğelerini Bir Windows Klasörüne Hızlı Bir Şekilde Dışa Aktarma

“Sık Kullanılanlar” bölümündeki tüm Outlook klasörlerini ve öğelerini dışa aktarmak isterseniz, bu makaleye başvurabilirsiniz. Burada size bunu hızlı bir şekilde nasıl başaracağınızı göstereceğiz.

Genellikle "Favoriler" bölümündeki klasörler ve içindeki öğeler büyük önem taşır ve sıklıkla ihtiyaç duyulur. Bu nedenle, bazen bunları yerel sürücüye aktarmak isteyebilirsiniz. Standart olarak, “Favoriler” içindeki klasörlere göre Windows klasörleri oluşturmanız ve öğeleri yerel sürücüde birer birer MSG dosyaları olarak kaydetmeniz gerekir. Bu çok sıkıcı. Bu nedenle, burada çok daha verimli bir yol göstereceğiz. Şimdi onu almak için okumaya devam edin.

“Favoriler” Bölümündeki Tüm Klasörleri ve Öğeleri bir Windows Klasörüne Aktarın

1. Başlamak için, Outlook'ta VBA düzenleyicisine “Outlook'unuzda VBA Kodunu Nasıl Çalıştırırsınız?".
2. Ardından, aşağıdaki kodu boş bir modüle kopyalayın.

Sub ExportAllFoldersItems_InFavorites_ToWindowsFolder()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFileSystem As Object
    Dim strWindowsFolder As String
    Dim objNavigationPane As Outlook.NavigationPane
    Dim objNavigationModule As Outlook.NavigationModule
    Dim objNavigationGroup As Outlook.NavigationGroup
    Dim objNavigationFolder As Outlook.NavigationFolder
    Dim objFolder As Outlook.Folder
    Dim strFolderPath As String
    Dim objItem As Object
    Dim strFilePath As String
    Dim i As Long
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
     
       'Get "Favorites" section
       Set objNavigationPane = Application.ActiveExplorer.NavigationPane
       Set objNavigationModule = objNavigationPane.Modules.GetNavigationModule(olModuleMail)
       Set objNavigationGroup = objNavigationModule.NavigationGroups.GetDefaultNavigationGroup(olFavoriteFoldersGroup)
 
       'Export the folders and items in "Favorites" section
       For Each objNavigationFolder In objNavigationGroup.NavigationFolders
           Set objFolder = objNavigationFolder.Folder
           strFolderPath = strWindowsFolder & objFolder.Name
           objFileSystem.CreateFolder strFolderPath
 
           For Each objItem In objFolder.Items
               strSubject = objItem.Subject
               strFileName = strSubject & ".msg"
 
               i = 0
               Do Until False
                  strFilePath = strFolderPath & "\" & strFileName
                  If objFileSystem.FileExists(strFilePath) Then
                     i = i + 1
                     strFileName = strSubject & " (" & i & ").msg"
                  Else
                     Exit Do
                  End If
               Loop
 
               objItem.SaveAs strFilePath, olMSG
          Next
       Next
 
       'Open the Windows folder
       Call Shell("explorer.exe " & strWindowsFolder, vbNormalFocus)
    End If
End Sub

3. Ardından, araç çubuğundaki "Çalıştır" simgesini tıklayın.
4. Ardından, açılır iletişim kutusunda bir hedef Windows klasörü seçin ve "Tamam"a tıklayın.
5. Makro bittiğinde, Windows klasörü görüntülenecektir.
6. Bu Windows klasöründe, aşağıdaki ekran görüntüsündeki gibi, “Favoriler” bölümündeki klasörler ve içindeki öğeler dışa aktarılmıştır.

Outlook Verilerini Yedeklerden Geri Yükle

Outlook dosyalarının düzenli aralıklarla yedeklenmesi önemle tavsiye edilir. Bunun nedeni, Outlook dosya bozulmasına maruz kalırsanız, Outlook'u kurtar yedeklerden kolayca veri. Ancak, böyle bir yedeğiniz yoksa, zorlu Outlook düzeltmesini denemeniz gerekir. O zaman, gelen kutusu onarım aracı pek yardımcı olmayacaktır. Gibi harici bir aracın düzeltilmesinden yardım almanız gerekir. DataNumen Outlook Repair.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. bozuk sql ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com