Belirli Slaytlar Nasıl Hızlı Bir Şekilde Eklenir? PowerPoint Outlook E-postanıza Sunum

Belirli slaytları ayıklamak istiyorsanız, PowerPoint sunuyu ayrı bir yeni sunuya dönüştürüp bir Outlook e-postasına eklemek için, bu makalede paylaşılan yöntemi kullanabilirsiniz.

bir bütün eklemek yerine PowerPoint sununun belirli slaytlarını eklemek istiyorsanız, genel olarak önce belirli slaytları yeni bir sunuya kopyalamanız gerekir. Bu çok zahmetli. Bu nedenle, burada size bunu tek seferde gerçekleştirebilecek bir yöntem göstereceğiz.

Belirli Slaytları Ekleyin PowerPoint Bir E-postaya Sunum

1. İlk olarak, spesifik olanı açın PowerPoint sunum.
2. Sonra, içinde PowerPoint uygulama penceresinde, VBA editörüne erişmek için “Alt + F11” tuşlarına basın.
3. Ardından, yeni pencerede “Ekle” > “Modül” seçeneğine basarak yeni bir modül oluşturun.
4. Ardından, aşağıdaki VBA kodunu kopyalayıp bu modüle yapıştırın.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Bundan sonra mevcut pencereyi kapatabilirsiniz.
6. Daha sonra, yeni makroyu Hızlı Erişim Araç Çubuğuna eklemek için “Dosya” > “Seçenekler” > “Hızlı Erişim Araç Çubuğu”na gidin.
7. Son olarak, bu makroyu deneyebilirsiniz.

• olaraktart, çıkartmak istediğiniz belirli slaytları seçin.
• Ardından, Hızlı Erişim Araç Çubuğundaki makro düğmesini tıklayın.
• Hemen, içinde bir Outlook e-postası görünecek. PowerPoint kaynak sunumdan çıkarılan sunum.

Etkili Bir Kurtarma Aracı Kullanın

Hepimizin bildiği gibi, Outlook yerleşik bir onarım yardımcı programı ile donatılmıştır - Tarama. Yine de, Outlook'taki küçük aksaklıklarla kolayca başa çıkabilir. Eğer karşı karşıya kaldığınız şey ciddi bir hasarsa, herhangi bir etki yaratmaz. Bu noktada, başka bir güçlü ve güvenilir onarım aracına dönmekten başka seçeneğiniz yok. DataNumen Outlook Repair. Bununla, bozuk Outlook dosyanızı kurtarabileceksiniz.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. bozuk mdf ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com