Bir Word Belgesinin Belirli Sayfalarını Bir Outlook E-postasına Hızlıca Ekleme

MS Word, kullanıcıların mevcut Word belgesini bir e-posta eki olarak göndermelerini destekleyen doğrudan bir özelliğe sahiptir. Ancak bazen, bir Word belgesinin yalnızca belirli sayfalarını bir Outlook e-postasına eklemeyi umabilirsiniz. Şimdi, bu makale size bir yöntem paylaşacak.

MS Word uygulamasında bir Word belgesinin tamamını e-posta eki olarak göndermek için, "Dosya" menüsüne gidip "Ek Olarak Gönder" düğmesini bulabileceğiniz "Kaydet ve Gönder" sekmesine geçebilirsiniz. Yine de bazen göndermek istediğiniz belgenin yalnızca belirli sayfaları olabilir. Bu durumda, bunu gerçekleştirmek için aşağıda açıklanan yöntemi kullanabilirsiniz.

Bir Word Belgesinin Belirli Sayfalarını Bir E-postaya Ekleyin

1. Öncelikle, belirli sayfalarını e-postayla göndermek istediğiniz kaynak Word belgesini açmalısınız.
2. Daha sonra MS Word penceresine girdikten sonra “Alt + F11” tuş butonlarına basmanız gerekmektedir.
3. Ardından, MS Word'deki VBA düzenleyicisine erişebileceksiniz.
4. Bundan sonra, “Microsoft Outlook Nesne Kitaplığı”nı etkinleştirmeniz gerekiyor. Bunu yapmak için “Araçlar” > “Referans” seçeneğine tıklayabilirsiniz.
5. Daha sonra aşağıdaki VBA kodunu kullanılmayan bir modüle kopyalamanız gerekmektedir.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Son olarak, bu makroyu çalıştırabilirsiniz. Sadece F5 tuş düğmesine basın veya araç çubuğundaki “Çalıştır” simgesine dokunun.
7. Makro tamamlandıktan sonra, aşağıdaki ekran görüntüsü gibi, kaynak Word belgesinden bir alıntı eklenmiş yeni bir Outlook e-postası görüntülenir:

Bozuk Outlook Dosyasından Maksimum Veriyi Çıkarın

Outlook'u onlarca yıldır kullandıysanız, açılır iç hata mesajları, ani çökmeler ve ciddi dosya hasarları gibi çeşitli Outlook sorunlarıyla karşı karşıya kalmış olabilirsiniz. Gerçek şu ki, Tarama, dahili onarım aracı, yalnızca küçük sorunlarla başa çıkabilir, harici güçlü bir düzeltme aracını elinizin altında bulundursanız iyi olur, diyelim DataNumen Outlook Repair. Zarar görmüş Outlook veri dosyasından maksimum veriyi çıkarabilir.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. sql düzeltmesi ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com