Outlook Takviminin Liste Görünümünde Tüm Doğum Günü Etkinlikleri için Karşılık Gelen Kişilerin Yaşlarını Gösterme

Bazı kullanıcılar, takvimde bir doğum günü etkinliğini görüntülerken ilgili kişinin yaşını da görmek ister. Bu nedenle, bu yazıda, bu fikri kolayca gerçeğe dönüştürmek için bir yöntem paylaşacağız.

Bir kişiye doğum günü bilgilerini eklediğinizde, Outlook otomatik olarak takvimde bir doğum günü etkinliği oluşturur. Bu durumda takvimde doğum günü olaylarını her gördüğünüzde ilgili kişilerin yaşlarını da almak isteyebilirsiniz. Böylece, burada size bunu gerçekleştirmenin bir yolunu tanıtacağız.

Liste Görünümünde Tüm Doğum Günü Etkinlikleri için Karşılık Gelen Kişilerin Yaşlarını Göster

1. En başta, Outlook VBA düzenleyicisini başlatın.
2. Ardından, aşağıdaki kodu bir modüle kopyalayın.

Sub ShowAgesOfBirthdayEventsListView()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Process All Calendar Folders in Your Outlook
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olAppointmentItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessFolders(ByVal objCalendar As Outlook.Folder)
    Dim i As Integer
    Dim objItem As Object
    Dim objBirthdayEvent As Outlook.AppointmentItem
    Dim dStart, dBirth As Date
    Dim nAge As Integer
    Dim objNewProperty As Outlook.UserProperty
    Dim objSubCalendar As Outlook.Folder

    For i = objCalendar.Items.Count To 1 Step -1
        Set objItem = objCalendar.Items.Item(i)
        'Add "Age" Property to Birthday Events
        If (objItem.MeetingStatus = olNonMeeting) And (objItem.IsRecurring = True) And (Right(objItem.Subject, 11) = "'s Birthday") Then
           Set objBirthdayEvent = objItem
           dStart = objBirthdayEvent.Start
 
           'Count Age
           dCurrentBirthday = DateSerial(Year(Now), Month(dStart), Day(dStart))
           nAge = DateDiff("yyyy", dStart, dCurrentBirthday)
 
           Set objNewProperty = objBirthdayEvent.UserProperties.Find("Age", True)
           If objNewProperty Is Nothing Then
              Set objNewProperty = objBirthdayEvent.UserProperties.Add("Age", olText, True)
           End If
 
           objNewProperty.value = nAge
           objBirthdayEvent.Save
        End If
    Next
 
    'Process All Sub-Calendar Folders Recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call ProcessFolders(objSubCalendar)
       Next
    End If
End Sub

3. Bundan sonra, imleci ilk alt programa getirin ve bu makroyu çalıştırmak için “F5” tuşuna basın.
4. Makro bittiğinde, VBA düzenleyicisinden çıkın ve bir takvim klasörü açın.
5. Daha sonra, “Görünüm” sekmesine gidin ve “Görünümü Değiştir” > “Liste”ye tıklayın.
6. Ardından, "Ayarları Görüntüle" düğmesini tıklayın.
7. Açılan iletişim kutusunda, "Sütunlar" ı seçin.
8. Ardından, sonraki "Sütunları Göster" iletişim kutusunda, "Kullanılabilir alanları şuradan seç" listesinden "Klasördeki kullanıcı tanımlı alanlar"ı seçin.
9. Daha sonra “Mevcut sütunlar” kutusuna “Yaş” girin ve “Ekle ->” düğmesine tıklayın.
10. Sonunda, takvim öğesi listesine geri dönene kadar bir dizi "Tamam" ı tıklayın.
11. Şimdi, listede, aşağıdaki şekilde gösterildiği gibi, tüm doğum günü etkinliklerinin kişilerin yaşlarını görebilirsiniz.

Ele Geçirilmiş Outlook Dosyasını Düzeltin

karşılaşınca paniğe kapılabilirsiniz. bozuk Outlook değerli e-postalarınızın ve programlarınızın çoğunu içeren dosya. Böyle bir sorun oldukça vahim olsa da, yine de bir an önce sakinleşmeli ve etkili önlemler almalısınız. Endişelenmeye devam ederseniz, durum daha da kötüleşebilir. Aslında, gelen kutusu onarım aracı ve daha sağlam ve deneyimli bir araç gibi hasarlı dosyayı onarabilecek birçok yol ve yardımcı program vardır. DataNumen Outlook Repair.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. SQL Server düzeltmek ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com