Bir Outlook Kişi Grubunun Tüm Üyelerini Excel'e Vermek için 2 Yöntem

Bazen, belirli bir Outlook kişi grubundaki üyeleri dışarı aktarmak isteyebilirsiniz. Bu nedenle, bu makale size grup üyelerini Excel'e ayıklamanın 2 yolunu paylaşacaktır.

Outlook, belirli bir kişi klasöründeki tüm kişileri dışa aktarmanıza izin veren yerel bir özellik sunar. Ancak, kişi gruplarını dışa aktarmanıza izin vermiyor, kişi gruplarındaki üyeleri ayıklamaktan bahsetmiyorum bile. Bu nedenle, seçilen bir kişi grubunun üyelerini çıkarmak isterseniz, biraz daha çaba göstermeniz gerekir. İşte başvurabileceğiniz iki ipucu.

Yöntem 1: Farklı Kaydet Yoluyla Grup Üyelerini Çıkarın

1. En başta, Outlook'u başlatın.
2. Ardından, üyelerini çıkarmanız gereken kişi grubunu bulun ve seçin.
3. Daha sonra “Dosya” menüsüne gitmeli ve “Farklı Kaydet” seçeneğine tıklamalısınız.
4. Ardından, açılan “Farklı Kaydet” iletişim kutusunda, kaydedilecek bir hedef klasör seçin ve “Tür olarak kaydet” açılır listesinden “Yalnızca Metin” seçeneğini seçin.
5. Ve ardından "Kaydet"i tıklayın.
6. Bundan sonra, Excel'i açın ve yeni bir excel dosyası oluşturun.
7. Daha sonra “Dosya”ya dönmeli ve “Aç” butonuna tıklamalısınız.
8. Sonraki "Aç" iletişim kutusunda, önce kişi grubunu şimdi kaydettiğiniz klasöre erişmelisiniz.
9. Ardından, "Dosya adı" satırındaki ikinci kutuyu tıklayın ve açılır listeden "Tüm Dosyalar" ı seçin.
10. Bundan sonra, kişi grubu için Metin dosyasına girin ve "Aç" düğmesine basın.
11. Açılan “Metin Alma Sihirbazı” iletişim kutusunda, “Sınırlandırılmış” öğesinin seçili olduğundan emin olun ve “Bitir” düğmesine tıklayın.
12. Sonunda, aşağıdaki ekran görüntüsü gibi üyeleri alacaksınız:

Yöntem 2: Grup Üyelerini Outlook VBA aracılığıyla ayıklayın

1. İlk olarak Outlook'ta “Alt + F11” tuşlarına basın.
2. Ardından VBA editör penceresinde yeni bir modül açın.
3. Ardından, aşağıdaki VBA kodlarını içine kopyalayın.

Sub ExtractContactGroupMembersToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objMember As Outlook.recipient
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strPath As String
    Dim strFilename As String
 
    Select Case Application.ActiveWindow.Class
           Case olExplorer
                Set objContactGroup = Application.ActiveExplorer.Selection(1)
           Case olInspector
                Set objContactGroup = Application.ActiveInspector.CurrentItem
    End Select
 
    If TypeOf objContactGroup Is DistListItem Then
       'Create a new Excel workbook
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkBook = objExcelApp.Workbooks.Add
       Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
       'Set the two column headers
       objExcelWorkSheet.Cells(1, 1) = "Contact Name"
       objExcelWorkSheet.Cells(1, 2) = "Email Address"

       nRow = 2
 
       'Extract the contact group members' names and email addresses
       For i = 1 To objContactGroup.MemberCount
           Set objMember = objContactGroup.GetMember(i)
           objExcelWorkSheet.Cells(nRow, 1) = objMember.Name
           objExcelWorkSheet.Cells(nRow, 2) = objMember.Address
           nRow = nRow + 1
       Next
 
       'AutoFit the columns in the new Excel worksheet
       objExcelWorkSheet.Columns("A:B").AutoFit
 
       'Change the strPath to your actual case
       strPath = "C:\Contact Groups\"
       strFilename = strPath & objContactGroup.DLName & ".xlsx"
 
       'Save the Excel workbook
       objExcelWorkBook.Close True, strFilename
 
       'Notify you of the export complete
       MsgBox ("Export Complete!")
    End If
End Sub

4. Bundan sonra, makroyu her zamanki gibi Hızlı Erişim Araç Çubuğuna (QAT) ekleyebilirsiniz.
5. Daha sonra, bir kişi grubu seçebilir ve QAT'ta makro düğmesine tıklayabilirsiniz.
6. Dışa aktardıktan sonra bir mesaj alacaksınız – “Dışa Aktarma Tamamlandı!”
7. Sonunda, Excel dosyasını VBA kodlarında önceden belirlenmiş olan klasörde bulabilirsiniz. Açın, aşağıdaki resimdeki gibi grup üyelerini görebilirsiniz:

Önceki PST Verilerinizi Geri Alın

Outlook çökmeye açık olduğundan, PST verileriniz herhangi bir alamet olmadan bozulabilir. Bu nedenle, PST dosyalarınızın düzenli bir yedeğini almalısınız. Ayrıca, güçlü bir araç hazırlamanız daha iyi olur, örneğin DataNumen Outlook Repairolabilir Outlook'u onar verileri zamanında

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. sql'yi düzelt ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com