Outlook'unuzdaki Tüm Okundu Bilgilerini Toplu Olarak Silme

Alıcıların e-postanızı okuduğunu doğrulamak için, e-postayı yazarken okundu bilgisi isteyebilirsiniz. Bu durumda, posta kutunuz bu tür okundu bilgileriyle dolup taşabilir. Şimdi, bu yazıda bunları kalıcı olarak toplu halde nasıl sileceğinizi öğreneceksiniz.

“ yazısını okuduktan sonraOutlook'unuzdaki Tüm Teslimat Makbuzlarını Toplu Olarak Silme“, tüm okundu bilgilerini toplu olarak silme yaklaşımını düşünebilirsiniz. Aslında iki makbuz türü arasındaki açık fark, bunların konularıdır. Teslimat fişi konusunda “Teslim Edildi” yazıyor ama okundu bilgisi bunun yerine “Okundu” içeriyor. Bu nedenle, tüm okundu bilgilerini toplu olarak silmek için aynı yöntemi kullanabilirsiniz. Aşağıda, size somut adımları ayrıntılı olarak öğreteceğiz.

Tüm Okundu Bilgilerini Toplu Olarak Sil

1. Öncelikle Outlook'u açın.
2. Ardından, “Alt + F11” aracılığıyla Outlook VBA düzenleyicisine “ göre gidin.Outlook'unuzda VBA Kodunu Nasıl Çalıştırırsınız?".
3. Ardından, yeni pencerede boş bir modül açın ve içine aşağıdaki kodu yazın.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Bundan sonra, ilk alt programa tıklayın.
5. Son olarak, “F5” tuş düğmesine basın.
6. Makro, Outlook'unuzdaki tüm okundu bilgilerini silmek için hemen çalışacaktır.
7. Bittiğinde, aşağıdaki ekran görüntüsü gibi sonuç hakkında bir bilgi istemi alacaksınız.
8. Şu anda posta klasörlerinizi kontrol edebilirsiniz. Tüm okundu bilgileri gitti.

Outlook Verilerini Savun

Outlook dosyasının bozulmaya açık olduğu kabul edilse de, onu korumak için önlemler alabiliriz. Örneğin Outlook dosyasını küçük boyutta tutmalı, kötü amaçlı etkenlerden korumalı ve düzenli olarak yedeklemeliyiz. Son olarak, güçlü bir harici PST onarım aracı hazırlasanız iyi olur. DataNumen Outlook Repair. Tamir üzerinde büyük etkiler yaratacaktır. bozuk Outlook dosyası.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. sql onarımı ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com