Farklı Renk Kategorilerinde Outlook Toplantıları İçin Farklı Hatırlatma Zamanlarını Otomatik Olarak Ayarlama

Outlook toplantılarını renk kategorilerine göre sınıflandırıyorsanız ve farklı renk kategorilerindeki toplantılar için farklı hatırlatma zamanı ayarlamak istiyorsanız bu makaleye başvurabilirsiniz. Burada size Outlook VBA ile gerçekleştirmeyi öğreteceğiz.

Örneğin, toplantıları iki gruba ayırıyorsunuz. Bir grup, toplantı yeri çok uzakta olduğu için "Ofis Dışı" renk kategorisinde, diğer grup ise toplantı yeri hemen burada olduğu için "Ofis İçi" renk kategorisinde yer alıyor. Şimdi, Outlook'un "ofis dışı" toplantılar için hatırlatma süresini başlangıçtan 1 saat önce, "ofis içi" toplantılar için ise başlangıçtan 15 dakika önce otomatik olarak ayarlamasını istiyorsunuz. Bu gereksinimi göz önünde bulundurarak, aşağıda hızlı bir yöntem paylaşacağız.

Farklı Renk Kategorilerindeki Toplantılar İçin Otomatik Olarak Farklı Hatırlatıcı Ayarla

1. Başlamak için Outlook uygulamanızı başlatın.
2. Ardından “Alt + F11” tuşlarına basarak VBA düzenleyici penceresine girin.
3. Ardından, sonraki pencerede, aşağıdaki VBA kodunu kopyalayıp “ThisOutlookSession” projesine yapıştırın.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Daha sonra, bu makroyu çalıştırmak için "Application_Startup" alt programına tıklayıp "F5" tuşuna basmanız gerekiyor.
5. O zamandan beri, varsayılan takvime her yeni toplantı eklendiğinde veya mevcut bir toplantıyı değiştirdiğinizde, Outlook toplantının kategorilerini otomatik olarak kontrol edecek ve farklı hatırlatma zamanını otomatik olarak ayarlayacaktır.

Outlook Hatalarını Ortadan Kaldırın

Outlook'ta zaman zaman çeşitli sorunlar ortaya çıkabilir. Bu nedenle, kullanıcıların Outlook sorunlarıyla nasıl başa çıkacaklarını öğrenmeleri son derece önemlidir. Başlangıç ​​olarak, düzenli Outlook veri yedeklemeleri yapmanızda fayda var. Ayrıca, eğer bütçeniz el veriyorsa, güçlü bir yedekleme sunucusu bulundurmanız önerilir. Outlook onarımı yakın araç, örneğin DataNumen Outlook Repair. Outlook sorunlarını anlamak ve ardından kolaylıkla çözmek için PST dosyanızı tarayabilir.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. sql kurtarma ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com