Her Gün Gelen E-postaların Toplam Sayısını Bir Excel Dosyasına Otomatik Olarak Kaydetme

Bu makale, Outlook'un her gün kaç tane e-posta aldığınızı otomatik olarak saymasına ve sayıyı bir Excel dosyasına yazmasına nasıl izin vereceğinizi öğretecektir.

Birçok kullanıcının her gün alınan toplam e-posta sayısını sayması gerekir. Ek olarak, gelecekte daha kolay kontrol için, birçoğu toplam sayımı bir Excel dosyasına kaydetmeye alışkındır. Bu durumda, elbette her gün manuel olarak saymayı ve kaydetmeyi seçebilirsiniz. Ancak biraz sıkıntılı. Ve bazen yapmayı unutabilirsin. Bu nedenle, Outlook'un bunu otomatik olarak yapmasını sağlayabilecek kullanışlı bir yöntem arzulamalısınız. Bu gereksinime yanıt olarak, bunu gerçekleştirmek için VBA'yı nasıl kullanacağınızı aşağıda size öğreteceğiz.

Her Gün Gelen E-postaların Toplam Sayısını Bir Excel Dosyasına Otomatik Olarak Kaydet

1. En başta, Outlook uygulamanızı başlatın.
2. Ardından, ana Outlook penceresindeki "Alt + F11" tuş kısayollarına basın.
3. Açılan VBA düzenleyici penceresinde, "ThisOutlookSession" projesini açın.
4. Ardından, aşağıdaki VBA kodlarını kopyalayıp bu projeye yapıştırın.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. Ardından, bu kodu imzalayın ve imzalı makrolara izin vermek için Outlook makro ayarlarınızı değiştirin.
6. Bundan sonra, günlük olarak yinelenen bir görev oluşturmanız gerekir.

• İlk olarak, Görevler bölmesinde “Yeni Görev” düğmesine tıklayın.
• Açılan Yeni Görev penceresinde, “Yineleme” düğmesine tıklayın.
• Ardından, sonraki iletişim kutusunda "Günlük", "Her 1 günde bir" ve "Bitiş tarihi yok" seçeneğini seçin ve son olarak "Tamam" düğmesine basın.
• Daha sonra görev konusunu ve hatırlatıcıyı ihtiyaçlarınıza göre değiştirin.
• Sonunda “Kaydet ve Kapat” düğmesine tıklayın.

7. Bundan sonra, bu görevin hatırlatıcı uyarıları her zaman, Outlook dün alınan e-postaları otomatik olarak sayacak ve ardından, aşağıdaki ekran görüntüsü gibi, sayıyı Excel dosyasına kaydedecek:

Kalıcı PST Veri Kaybından Kaçış

Hiç kimse kalıcı PST veri kaybını kabul etmeye istekli değildir. Ancak, Outlook PST dosyası bozulmaya eğilimlidir. Bu nedenle, tutarlı ve güncel bir PST veri yedeklemesi yapmak ve güçlü bir veri tabanı oluşturmak gibi yeterli önlemleri almalısınız. PST kurtarma civardaki araç gibi DataNumen Outlook Repair.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. sql onarımı ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com