Bilinmeyen Gönderenlerden Gelen Outlook E-postalarındaki Köprüleri Otomatik Olarak Devre Dışı Bırakma

Kötü amaçlı bağlantıları engellemek için, Outlook'unuzu bilinmeyen gönderenlerden gelen e-postalardaki köprüleri otomatik olarak devre dışı bırakacak şekilde yapılandırmanız daha iyi olur. Bu makale, mantar gibi almanıza yardımcı olabilecek bir parça VBA kodunu ortaya çıkaracaktır.

Birçok kullanıcı, e-posta kaynaklı virüslerin Outlook dosyalarına saldırdığından şikayet etti. Çoğu zaman bunun nedeni, bilinmeyen gönderenlerden gelen e-postalara kolayca güvenmeleridir. Böylece postalardaki köprüleri indirir veya tıklarlar. Şimdi bundan sonra bir yöntem paylaşacağız. Bilinmeyen göndericilerden gelen e-postaların köprülerini Outlook'un otomatik olarak devre dışı bırakmasına izin verebilir. Bu tür ihtiyaçlarınız varsa, daha fazla ayrıntı almak için lütfen okumaya devam edin.

Bilinmeyen Gönderenlerden Gelen E-postalardaki Köprüleri Otomatik Olarak Devre Dışı Bırak

1. Öncelikle Outlook'ta "Alt + F11" tuş kombinasyonunu kullanarak VBA düzenleyicisine gidin.
2. Ardından, yeni ekranda, "MS VBScript Düzenli İfadeler" nesnesini, " başlıklı gönderide belirtildiği gibi ekleyin.VBA'da Nesne Kütüphanesi Referansı Nasıl Eklenir?".
3. Ardından, aşağıdaki kodu kopyalayıp “ThisOutlookSession” projesine yapıştırın.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

4. Bundan sonra, Outlook'u yeniden başlatarak veya "Application_Startup" alt programında "F5" tuşuna basarak bu makroyu etkinleştirin.
5. O zamandan beri, gönderenden gelen ve varsayılan Kişi klasöründe saklanmayan bir e-posta Gelen Kutusu'na her girdiğinde, Outlook içindeki köprüleri otomatik olarak devre dışı bırakır.

Outlook Korumasında Birkaç Gereklilik Konusu

Outlook hasara açık olduğundan, Outlook dosyasını korumak oldukça zordur. Burada, Outlook veri koruması sırasında sahip olunması gereken birkaç şeyi listeleyeceğiz. Her şeyden önce, Outlook verilerinizi düzenli olarak yedeklemeniz gerekir. Ayrıca, kötü amaçlı ekler veya köprüler gibi tüm potansiyel risklere karşı dikkatli olmanız önemlidir. Son fakat en az değil, önceden güçlü bir Outlook düzeltme aracı hazırlamanız gerekir, örneğin DataNumen Outlook Repair. İhtiyacınız olduğunda kesinlikle kullanışlı olacaktır PST'yi onar dosya ama gelen kutusu onarım aracı başarısız olduğunu kanıtlıyor.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. hasarlı mdf ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com