Word Belgenizdeki Resimlerden Köprüleri Kaldırmanın 3 Hızlı Yolu

Bu yazıda, Word belgenizdeki resimlerden köprüleri kaldırmanın 3 hızlı yolunu göstermek istiyoruz.

Bazen, çevrimiçi bir resmi kopyalarken, onu bir köprü ile katıştırılmış olarak buluruz. Ve bir Word belgesinde, yanlışlıkla resme tıklamak sizi resmin net adresine yönlendirebilir. Bu sadece rahatsız edici olmakla kalmaz, aynı zamanda aşağıdaki gibi belgenizin görsel etkisini de bozar:

Bu nedenle, bu tür beklenmedik sayfa atlamalarından kaçınmak için resimlerden köprüleri kaldırmayı seçiyoruz. İşte başlıyoruz.

Yöntem 1: Köprüyü bir Resimden Kaldırma

1. İlk olarak, bir resme sağ tıklayın.
2. Ardından bağlamsal menüde "Köprüyü Kaldır"ı seçin.

Yöntem 2: Bir Belgedeki Tüm Resimlerden Köprüleri Toplu Olarak Kaldırma

Bir belgedeki tüm köprüleri kaldırmanın bir yolu vardır. Önce tüm içeriği seçmek için “Ctrl+A” tuşlarına basın. Ardından, tüm köprüleri öldürmek için "Ctrl + Shift + F9" tuşlarına basın. Bilginiz olsun, bu şekilde hem resimlerdeki hem de metinlerdeki tüm köprüler temizlenir. Ancak amacımız sadece resimlerdeki köprüleri kaldırmaktır. Bu yüzden işi bitirmek için bir makro kullanmamız gerekecek.

1. Her şeyden önce, Word'de VBA düzenleyicisini tetiklemek için “Alt + F11” tuşlarına basın.
2. Ardından editörde “Normal” projeye tıklayın.
3. Sonraki menü çubuğunda, "Ekle" yi tıklayın.
4. Ve açılır menüden "Modül"ü seçin.
5. Şimdi sağdaki kodlama alanını açmak için modüle çift tıklayın ve aşağıdaki makroyu oraya yapıştırın:

Sub RemoveAllHyperlinksFromPicturesInOneDocument()
  Dim objInlinePicture As InlineShape
  Dim objPicture As Shape
 
  If ActiveDocument.InlineShapes.Count > 0 Then 
    For Each objInlinePicture In ActiveDocument.InlineShapes
      objInlinePicture.Select
 
      While Selection.Hyperlinks.Count > 0
        Selection.Hyperlinks(1).Delete
      Wend 
    Next
  End If

  If ActiveDocument.Shapes.Count > 0 Then 
    For Each objPicture In ActiveDocument.Shapes 
      objPicture.Select
 
      While Selection.Hyperlinks.Count > 0
        Selection.Hyperlinks(1).Delete
      Wend 
    Next 
  End If
End Sub

6. Son olarak, kodları çalıştırmak için menü çubuğundaki "Çalıştır"a tıklayın.

Yöntem 3: Birden Çok Belgedeki Resimlerden Köprüleri Toplu Olarak Kaldırma

1. Öncelikle, hedef belgelerin tamamını tek bir klasörde düzenleyin.
2. Ardından, aşağıdaki makroyu yüklemek ve çalıştırmak için yöntem 2'deki adımları tekrarlayın:

Sub RemoveAllHyperlinksFromPicturesInMultipleDocuments()
  Dim objInlinePicture As InlineShape
  Dim objPicture As Shape
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
 
    If ActiveDocument.InlineShapes.Count > 0 Then
      For Each objInlinePicture In ActiveDocument.InlineShapes
        objInlinePicture.Select 
        While Selection.Hyperlinks.Count > 0
          Selection.Hyperlinks(1).Delete
        Wend
      Next
    End If

    If ActiveDocument.Shapes.Count > 0 Then
      For Each objPicture In ActiveDocument.Shapes
        objPicture.Select 
        While Selection.Hyperlinks.Count > 0
          Selection.Hyperlinks(1).Delete
        Wend
      Next
    End If

    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    strFile = Dir()
  Wend
End Sub

3. Açılan “Gözat” penceresinde, 1. adımda belirlediğiniz klasörü seçin ve devam etmek için “Tamam”a tıklayın.

Word'deki İşlemleriniz Konusunda Dikkatli Olun

Word kusursuz değildir, bu nedenle herhangi bir yanlış işlem kolayca çökmeyi veya daha kötüsünü tetikleyerek belgenin bozulmasına neden olabilir. Operasyon becerilerinize ve alışkanlıklarınıza daha fazla dikkat edebilirken, aynı zamanda bir yardımcı program satın alabilirsiniz. doktor kurtarma önceden.

Yazar Tanıtımı:

Vera Chen bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. xls'i kurtar hem de pdf onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com