Farklı Sayfalarda Farklı Kategorilere Sahip Outlook Görevlerinin Listelerini Yazdırmanın 2 Yolu

Outlook görevlerinize çeşitli renk kategorileri atadıysanız ve şimdi farklı kategorilerdeki görev listelerini farklı sayfalarda yazdırmak istiyorsanız, bu makaleye başvurabilirsiniz. İşte bunu elde etmek için 2 yöntemi sizlerle paylaşacağız.

Görevlerinizi sınıflandırmak ve iyi yönetmek için belki de görevlerinize renk kategorileri uygulamışsınızdır. Şimdi, farklı kategorilerdeki görev listelerinizi farklı sayfalarda yazdırmak isterseniz, lütfen okumaya devam edin. Aşağıda, onu elde etmenin 2 yolunu size tanıtacağız.

Yöntem 1: Görev Listelerini Tek Tek El İle Yazdır

1. Öncelikle, Outlook'ta "Görevler" bölmesine erişin.
2. Ardından, bir Görev klasörü açın.
3. Ardından, "Ara" şeridini etkinleştirmek için "Ctrl + E" tuşlarına basın.
4. Ardından “Ara” sekmesinde “Kategorize Et” butonuna tıklayın.
5. Açılır listeden bir renk kategorisi seçin.
6. Ardından, listede yalnızca seçilen kategorideki görevler kalacaktır.
7. Şimdi, bu görev listesini yazdırmak için “Dosya” > “Yazdır” seçeneğine gidin.
8. Daha sonra, aynı şekilde, diğer renk kategorileri ile görev listelerini birer birer manuel olarak yazdırın.

Yöntem 2: Görev Listelerini VBA ile Toplu Yazdırın

1. En başta, VBA editörünü “ uyarınca tetikleyin.Outlook'unuzda VBA Kodunu Nasıl Çalıştırırsınız?".
2. Ardından, "MS Excel Nesne Kitaplığı"na yapılan referansı aşağıdaki gibi ekleyin:VBA'da Nesne Kütüphanesi Referansı Nasıl Eklenir?".
3. Ardından, aşağıdaki VBA kodunu bir modüle kopyalayın.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Daha sonra bu makroyu hemen çalıştırmak için “F5” tuşuna basınız.
5. Makro tamamlandığında, aşağıdaki ekran görüntüsünde gösterildiği gibi, farklı kategorilerdeki görev listeleri farklı sayfalara yazdırılacaktır.

Ele Geçirilmiş PST Dosyasından Değerli Verileri Geri Alın

Erişilemeyen PST dosyasına tabi iseniz, bir sonraki adımınız şüphesiz PST onarımı. Bu durumda, öncelikle gelen kutusu onarım aracını deneyebilirsiniz. Başarısız olması koşuluyla, aşağıdaki gibi başka bir harici aracı denemeye devam edebilirsiniz. DataNumen Outlook Repair. PST verilerini hızlı bir şekilde kurtarabilir.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. mdf'yi kurtar ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com