İşaretlenen Tüm Outlook E-postalarının Listesini Excel'e Aktarmanın 2 Hızlı Yolu

Outlook posta kutunuzdaki tüm işaretli e-postaların listesini Excel'e aktarmak isterseniz, bu makalede paylaşılan 2 yöntemden birini kullanabilirsiniz.

Örneğin, işaretlenen tüm e-postalarla daha zamanında ilgilenmek veya başka biriyle paylaşmak için bunları bir Excel çalışma sayfasına aktarmayı umabilirsiniz. Burada bunu gerçekleştirmek için 2 yaklaşımı tanıtacağız. İlki, işaretli e-postaları bulduktan sonra standart "İçe ve Dışa Aktar" özelliğini kullanır. Dürüst olmak gerekirse, biraz sıkıcı. Bu nedenle, ikincisinde size VBA'yı uygulamanın daha uygun bir yolunu öğreteceğiz.

Yöntem 1: Bulunan Tüm İşaretlenmiş E-postaları Manuel Olarak Dışa Aktarın

1. Her şeyden önce, posta listesinin üstündeki arama kutusuna tıklayın.
2. Daha sonra “Arama” sekmesindeki “Kapsam” grubunda “Tüm Posta Öğeleri”ne tıklayın.
3. Ardından, "Tanımla" grubundaki "Bayraklı" düğmesini tıklayın.
4. Listede gösterilen tüm işaretli e-postalardan sonra, bir posta seçin ve hepsini seçmek için “Ctrl + A” tuşlarına basın.
5. Ardından, “Ctrl + Shift + V” tuş kısayollarına basın.
6. Yeni iletişim kutusunda, Outlook dosyası altında yeni bir klasör oluşturun.
7. Daha sonra, yeni oluşturulan klasörü seçin ve bulunan tüm işaretli e-postaları yeni klasöre taşıyacak olan "Tamam"a tıklayın.
8. Daha sonra “Dosya” > “Aç” > “İçe Aktar”a tıklayın,
9. Açılır iletişim kutusunda, "Dosyaya aktar" > "İleri" > "Microsoft Excel 97-2003" > "İleri"yi seçin.
10. Yeni ekranda, doğru klasörü seçin ve “İleri” düğmesine basın.
11. Daha sonra, "Dışa Aktar" işlemini tamamlamak için sihirbazları izleyin.
12. Aşağıdaki ekran görüntüsünde gösterilen yeni bir Excel dosyası alacaksınız.

Yöntem 2: İşaretlenen Tüm E-postaların Listesini VBA aracılığıyla Dışa Aktarın

1. Outlook'ta, VBA düzenleyicisini tetiklemek için “Alt + F11” tuşlarına basın.
2. Ardından, "MS Excel Nesnesi" ni "" uyarınca etkinleştirin.VBA'da Nesne Kütüphanesi Referansı Nasıl Eklenir?".
3. Ardından, aşağıdaki VBA kodunu bir modüle kopyalayın.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Son olarak, imleci “ExportAllFlaggedEmailsToExcel” alt programına getirin ve “F5” tuşuna basın.
5. Ardından, yeni iletişim kutusunda bir Outlook dosyası seçin.
6. “Completed” uyarısını gördüğünüzde aşağıdaki görseldeki gibi yeni bir Excel dosyası da alacaksınız.

Görünümünüzü Bozulmaya Karşı Koruyun

Outlook hatalara ve veri bozulmalarına yatkındır, bu nedenle Outlook verilerimizi korumak bizim için çok zorlu bir iştir. Şüphesiz en etkili ve pratik yol, Outlook için düzenli veri yedeklemeleri yapmaktır. Buna ek olarak, güçlü ve güvenilir bir Outlook onarım aracına da sahip olmamız gerekmektedir, örneğin... DataNumen Outlook Repair. Olursa işine yarar gelen kutusu onarım aracı hiçbir etkisi yoktur.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. düzeltmek SQL Server ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com