Word Belgenizdeki Vurgulanan Kelimelerin Sayısını Saymanın 2 Hızlı Yolu

Bu yazıda, Word belgenizdeki vurgulanan sözcükleri saymanın 2 hızlı yolunu sunmak istiyoruz.

Zaman zaman farklı konulardaki metinleri farklı renklerle ön plana çıkarırdık. Vurgulanan sözcüklerin toplam sayısını saymak istemeniz durumunda, Word'de bu görevi gerçekleştirmenin doğrudan bir yolu olmadığını anlamalısınız. Ancak geçici çözüm olarak, farklı durumlarda aşağıdaki yöntemlerden birini seçebilirsiniz.

Yöntem 1: Vurgulanan Tüm Kelimeleri Farklı Renklerde Say

1. Her şeyden önce, Word'de VBA düzenleyicisini açmak için “Alt + F11” tuşlarına basın.
2. Ardından sol sütundaki “Normal”e tıklayın.
3. Ardından, menü çubuğundaki "Ekle" düğmesini tıklayın.
4. Açılır menüden "Modül"ü seçin.

5. Ve açmak için yeni modüle çift tıklayın.
6. Aşağıdaki makroyu oraya yapıştırın:

Sub CountAllWordsInHighlight()
    Dim objWord As Range
    Dim nHighlightedWords As Long
    Dim objDoc As Document
 
    Application.ScreenUpdating = False
    Set objDoc = ActiveDocument
 
    With Selection
         .HomeKey Unit:=wdStory
         With Selection.Find
              .Highlight = True
 
              Do While .Execute
                       nHighlightedWords = nHighlightedWords + Selection.Range.ComputeStatistics(wdStatisticWords)
                       Selection.Collapse wdCollapseEnd
              Loop
         End With
    End With
 
    MsgBox ("The total number of highlighted words is " & nHighlightedWords & " .")
 
    Application.ScreenUpdating = True
    Set objDoc = Nothing
End Sub

7. Son olarak, kodları çalıştırmak için "Çalıştır" düğmesini tıklayın veya "F5" tuşuna basın.

Aşağıdaki gibi bir mesaj kutusu görünecektir:

Yöntem 2: Vurgulanan Tüm Kelimeleri Belirli Bir Renkte Say

Yukarıda belirttiğimiz gibi, Word belgenize uygulanmış birkaç vurgu rengi olabilir. Bu nedenle, belirli bir renkteki vurgulanan kelimelerin kelime sayısını bulmak biraz zor. Neyse ki, bazı özelleştirilmiş görevleri yapmak için her zaman makroya güvenebiliriz.

1. Her şeyden önce, bir makro yüklemek ve çalıştırmak için yöntem 1'deki adımları tekrarlayın.
2. Ardından bu makro ile değiştirin:

Sub CountWordsInASpecificHighlightColor()
    Dim objDoc As Document
    Dim objWord As Object
    Dim nHighlightedWords As Long
    Dim strHighlightColor As String
 
    Application.ScreenUpdating = False
    Set objDoc = ActiveDocument
    nHighlightedWords = 0
    strHighlightColor = InputBox("Choose a Highlight colour (enter the value):" & vbNewLine & _
      vbTab & "Auto" & vbTab & vbTab & "0" & vbNewLine & _
      vbTab & "Black" & vbTab & vbTab & "1" & vbNewLine & _
      vbTab & "Blue" & vbTab & vbTab & "2" & vbNewLine & _
      vbTab & "BrightGreen" & vbTab & "4" & vbNewLine & _
      vbTab & "DarkBlue" & vbTab & vbTab & "9" & vbNewLine & _
      vbTab & "DarkRed" & vbTab & vbTab & "13" & vbNewLine & _
      vbTab & "DarkYellow" & vbTab & "14" & vbNewLine & _
      vbTab & "Gray25" & vbTab & vbTab & "16" & vbNewLine & _
      vbTab & "Gray50" & vbTab & vbTab & "15" & vbNewLine & _
      vbTab & "Green" & vbTab & vbTab & "11" & vbNewLine & _
      vbTab & "Pink" & vbTab & vbTab & "5" & vbNewLine & _
      vbTab & "Red" & vbTab & vbTab & "6" & vbNewLine & _
      vbTab & "Teal" & vbTab & vbTab & "10" & vbNewLine & _
      vbTab & "Turquoise" & vbTab & "3" & vbNewLine & _
      vbTab & "Violet" & vbTab & vbTab & "12" & vbNewLine & _
      vbTab & "White" & vbTab & vbTab & "8" & vbNewLine & _
      vbTab & "Yellow" & vbTab & vbTab & "7", "Pick Highlight Color")
 
    For Each objWord In objDoc.Words
        If objWord.HighlightColorIndex = strHighlightColor Then
           nHighlightedWords = nHighlightedWords + 1
        End If
    Next objWord
 
    MsgBox ("The number of highlighted words is " & nHighlightedWords & " .")
 
    Application.ScreenUpdating = True
    Set objDoc = Nothing
End Sub

3. Sonraki “Vurgu Rengini Seç” kutusuna bir renk değeri girin ve “Tamam”a tıklayın. Örneğin buraya sarı rengi temsil eden “7” giriyoruz.
4. Şimdi sonuç şu:

Belge Bozulması Sorununu Akıllıca Çözün

Şimdi ve sonra, karşılaşabileceğiniz Kelime hasarı. En kötüsü, bozuk belgelere yol açabilmesidir. Belgenizi kurtarmak için Word'deki yerleşik özelliği kullanabilirken, verilerinizi en kısa sürede kurtarmak için bir onarım aracı almak gibi başka bir akıllı seçeneğe de başvurabilirsiniz.

Yazar Tanıtımı:

Vera Chen bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. bozuk xls hem de pdf onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com