วิธีตั้งค่าแบบอักษรเริ่มต้นสำหรับเนื้อหาของการติดต่อการนัดหมายและงานผ่าน VBA

Outlook ไม่มีคุณลักษณะดั้งเดิมในการตั้งค่าแบบอักษรเริ่มต้นสำหรับเนื้อหาของผู้ติดต่อการนัดหมายและรายการงาน ดังนั้นหากคุณต้องการระบุแบบอักษรคุณสามารถใช้วิธีการที่แนะนำในบทความนี้

เช่นเดียวกับอีเมลการนัดหมายใน Outlook งานและที่ติดต่อก็มีช่องเนื้อหาซึ่งเราสามารถกรอกรายละเอียดรายการได้ อย่างไรก็ตาม Outlook อนุญาตให้ผู้ใช้ตั้งค่าแบบอักษรเริ่มต้นที่ใช้ในเนื้อหาอีเมลเท่านั้น หากคุณต้องการระบุแบบอักษรในเนื้อหาของการติดต่อการนัดหมายหรืองานคุณต้องแสวงหาวิธีการอื่นเช่น Add-in ของบุคคลที่สามหรือ Outlook VBA ที่นี่เราจะสอนวิธีใช้ VBA อย่างละเอียดเพื่อรับมัน อ่านเพื่อเรียนรู้ขั้นตอนโดยละเอียดและรหัส VBA ที่เกี่ยวข้อง

ตั้งค่าแบบอักษรเริ่มต้นสำหรับเนื้อหาของการนัดหมายงานและที่ติดต่อ

1. เมื่อเริ่มแรก starโปรแกรม Outlook ของคุณ
2. จากนั้นกดปุ่ม“ Alt + F11” เพื่อเปิดโปรแกรมแก้ไข Outlook VBA
3. ในหน้าต่างป๊อปอัปคุณต้องเปิดโครงการ“ ThisOutlookSession”
4. จากนั้นคัดลอกรหัส VBA ต่อไปนี้ลงในหน้าต่างโครงการนี้

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objInspector As Outlook.Inspector

Public Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Public Sub objInspectors_NewInspector(ByVal Inspector As Outlook.Inspector)
    Set objInspector = Inspector
End Sub

Public Sub objInspector_Activate()
    Dim objCurrentItem As Object
    Dim objCurrentInspector As Outlook.Inspector
    Dim objWordDocument As Word.Document
    Dim objWordSelection As Word.Selection
 
    Set objCurrentItem = objInspector.CurrentItem
    Set objCurrentInspector = objCurrentItem.GetInspector
    Set objWordDocument = objCurrentInspector.WordEditor
    Set objWordSelection = objWordDocument.Application.Selection
 
    'You change the font as per your preference
    Select Case objCurrentItem.Class
           Case olContact
                With objWordSelection.Font
                     .Name = "Segoe Script"
                     .ColorIndex = wdRed
                     .Size = 8
                     .Bold = True
                End With
           Case olAppointment
                With objWordSelection.Font
                     .Name = "Comic Sans MS"
                     .ColorIndex = wdBlue
                     .Size = 9
                     .Bold = False
                End With
           Case olTask
                With objWordSelection.Font
                     .Name = "MV Boli"
                     .ColorIndex = wdGreen
                     .Size = 10
                     .Bold = True
                End With
   End Select
End Sub

5. หลังจากนั้นคุณต้องเซ็นรหัสนี้

• ขั้นแรกให้สร้างใบรับรองดิจิทัลโดยใบรับรองดิจิทัลสำหรับโครงการ VBA
• จากนั้นกำหนดใบรับรองนี้ให้กับมาโครใหม่

6. ในภายหลังคุณสามารถเปลี่ยนการตั้งค่าแมโคร Outlook ของคุณเพื่ออนุญาตแมโครที่เซ็นชื่อแบบดิจิทัล
7. ในที่สุดคุณtart Outlook ของคุณเพื่อเปิดใช้งานโครงการ VBA ใหม่ จากนี้ไปเมื่อคุณสร้างผู้ติดต่อการนัดหมายหรืองานใหม่เนื้อหาจะใช้แบบอักษรเริ่มต้นเช่นภาพหน้าจอต่อไปนี้:

ปกป้องข้อมูล PST ของคุณจากการทุจริต

เนื่องจากไฟล์ Outlook PST มีแนวโน้มที่จะเกิดข้อผิดพลาดและเสียหายคุณจึงต้องให้ความสำคัญกับการป้องกัน PST เป็นอย่างมาก ตัวอย่างเช่นคุณควรระวังอีเมลจากแหล่งที่มาที่ไม่รู้จักซึ่งอาจเป็นอีเมลที่เป็นอันตรายที่มีไวรัส เมื่อไฟล์ PST ของคุณติดไวรัสคุณต้องกลับมาใช้เครื่องมือแก้ไขที่มีชื่อเสียงและได้รับการพิสูจน์แล้วเช่น DataNumen Outlook Repair, ซึ่งสามารถ ซ่อม PST ไฟล์เหมือนสายลม

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ แก้ไขปัญหา SQL Server และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.