Como salvar em lote vários rascunhos de e-mail como modelos do Outlook

Talvez você tenha criado vários rascunhos de e-mail e espere reutilizá-los muitas vezes. Em caso afirmativo, por que você não os salva em lote como modelos do Outlook? Este artigo irá ensiná-lo a realizá-lo de uma só vez via VBA.

Por padrão, o Outlook permite apenas que os usuários salvem um único email como modelo de uma só vez. Em outras palavras, você não pode salvar vários rascunhos de e-mail como modelos em massa. Como você pode ver, ao selecionar mais de um e-mail e ir em “Arquivo” > “Salvar como”, não é possível encontrar o formato “Modelo do Outlook” na lista “Salvar como tipo”, apenas “Somente texto” disponível. Porém, apresentaremos a você como realizá-lo em massa a seguir.

Lote Salvar vários rascunhos de e-mail como modelos do Outlook

1. No início, acione o editor VBA do Outlook.
2. Na nova janela “Microsoft Visual Basic for Applications”, copie e cole o código VBA abaixo.

Sub SaveMultipleDraftsAsTemplates()
    Dim objSelection As Outlook.Selection
    Dim i As Long
    Dim strTemplateFolder As String
    Dim objMail As Outlook.MailItem
    Dim strSubject As String
 
    'Get all selected mails
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
       'Get the default folder for saving Outlook Templates
       strTemplateFolder = CStr(Environ("USERPROFILE")) & "\Documents\UserTemplates\"
 
       'Save each mail as template
       For i = objSelection.Count To 1 Step -1
           If objSelection(i).Class = olMail Then
              Set objMail = objSelection(i)
              If objMail.Subject <> "" Then
 
                 'Remove unsupported characters
                 strSubject = objMail.Subject
                 strSubject = Replace(strSubject, "/", " ")
                 strSubject = Replace(strSubject, "\", " ")
                 strSubject = Replace(strSubject, ":", "")
                 strSubject = Replace(strSubject, "?", " ")
                 strSubject = Replace(strSubject, Chr(34), " ")
 
                 objMail.SaveAs strTemplateFolder & strSubject & ".oft", olTemplate
              Else
                 objMail.SaveAs strTemplateFolder & "Template" & i & ".oft", olTemplate
              End If
           End If
       Next
 
       'Open the folder of Templates
       Shell "Explorer.exe" & " " & strTemplateFolder, vbNormalFocus
    End If
End Sub

3. Depois disso, para conveniência posterior, sugere-se anexar esta macro à Barra de Ferramentas de Acesso Rápido (QAT). Sobre as etapas detalhadas, você pode ler “Como executar o código VBA no seu Outlook"
4. Por fim, você pode tirar uma foto seguindo as operações abaixo.

• Primeiro, selecione os rascunhos de e-mails a serem salvos como modelos.
• Em seguida, clique no botão macro no QAT.
• Quando a macro terminar, a pasta do Windows para salvar os modelos padrão do Outlook será exibida. Você pode ver que os modelos dos rascunhos de e-mail selecionados estão ali.

A ferramenta de reparo da caixa de entrada ainda pode falhar

Quando se trata da ferramenta interna de correção do Outlook - Scanpst, um grande número de usuários irá apreciá-la. Sem dúvida, este utilitário é realmente capaz de resolver a maioria dos pequenos problemas no Outlook. No entanto, não é totalmente impecável. Ele ainda pode falhar e trazer muitos erros. Por exemplo, em caso de grave Corrupção do Outlook, não é possível reparar o arquivo PST comprometido. Nesse cenário, você não tem alternativa a não ser usar uma ferramenta de terceiros mais poderosa e de ponta, como DataNumen Outlook Repair.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo recuperação sql e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com