Windows хавтас дахь бүх Outlook мессежийн файлуудаас хавсралтыг хэрхэн хурдан задлах вэ

Магадгүй та олон Outlook имэйлийг Windows хавтсанд .msg форматаар хадгалсан байх. Дараа нь та эдгээр файлуудаас хавсралтуудыг задлахыг хүсвэл энэ нийтлэлд хуваалцсан аргыг ашиглаж болно.

Outlook дээрх имэйлүүдээс хавсралтуудыг задлахад маш хялбар байдаг. Харин Windows хавтсанд .msg файл хэлбэрээр экспортлогдсон имэйлүүдийг яах вэ? Ерөнхийдөө та эхлээд эдгээр .msg файлуудыг Outlook дээрээ нээж, дараа нь хавсралтуудыг нэг нэгээр нь хадгалах хэрэгтэй. Магадгүй танд хэтэрхий төвөгтэй санагдах байх. Тиймээс, дараа нь бид танд өөр илүү хурдан шийдлийг заах болно.

Windows хавтас дахь бүх Outlook мессежийн файлуудаас хавсралтыг задлах

1. Эхлэхийн тулд start Outlook програмаа суулгаад VBA засварлагчийг ажиллуулна уу.
2. Дараа нь “Програмд ​​зориулсан Microsoft Visual Basic” цонхонд доорхи VBA кодыг ашиглагдаагүй модуль руу хуулж ав.

Dim strAttachmentFolder As String

Sub ExtractAttachmentsFromEmailsStoredinWindowsFolder()
    Dim objShell, objWindowsFolder As Object
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       'Create a new folder for saving extracted attachments
       strAttachmentFolder = "E:\Attachments-" & Format(Now, "MMDDHHMMSS") & "\"
       MkDir (strAttachmentFolder)
       Call ProcessFolders(objWindowsFolder.self.Path & "\")
       MsgBox "Completed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFiles As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim i As Long
    Dim objSubFolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
    Set objFiles = objFolder.Files
 
    For Each objFile In objFiles
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           'Open the Outlook emails stored in Windows folder
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              If objItem.Attachments.Count > 0 Then
                 'Extract attachments
                 For i = objItem.Attachments.Count To 1 Step -1
                     objItem.Attachments(i).SaveAsFile strAttachmentFolder & objItem.Attachments(i).FileName
                 Next
              End If
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubFolder In objFolder.SubFolders
           If ((objSubFolder.Attributes And 2) = 0) And ((objSubFolder.Attributes And 4) = 0) Then
              Call ProcessFolders(objSubFolder.Path)
           End If
       Next
    End If
End Sub

3. Дараа нь курсорыг эхний дэд програм руу шилжүүлж, "F5" товчийг дарна уу.
4. Дараа нь гарч ирэх харилцах цонхонд та Windows-ийн эх хавтсыг сонгохыг шаардах болно.
5. "OK" дээр дарсны дараа макро ажиллах болно.
6. Энэ нь дууссаны дараа та "Дууссан" гэсэн мессежийг хүлээн авах болно.
7. Одоо та задалсан хавсралтуудыг хадгалахын тулд урьдчилан тодорхойлсон дотоод хавтсанд хандах боломжтой.

Төлөвийн асуудлуудыг үр дүнтэй шийдвэрлэх

Outlook нь алдаа гаргах магадлалтай тул Outlook объектуудтай харьцахдаа болгоомжтой байх хэрэгтэй, тухайлбал үл мэдэгдэх имэйлд суулгагдсан файл, холбоосуудад хэзээ ч итгэхгүй байх гэх мэт. Үгүй бол таны Outlook файл амархан эвдэрч болзошгүй. Ийм нөхцөлд дотоод засах хэрэгсэл ч гэсэн тийм ч их тус болохгүй. Таны ашиглаж болох зүйл бол зөвхөн туршлагатай гадны хэрэгсэл юм DataNumen Outlook RepairБайна. Ингэж чаддаг PST засах хялбар файл.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. эвдэрсэн кв програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com