Өнгө ангилал бүрийн Outlook уулзалтанд зарцуулсан нийт хугацааг хэрхэн хурдан экспортлох вэ

Хэрэв та өнгөний ангилал тус бүрт цаг товлоход зарцуулсан нийт хугацааныхаа тайланг гаргахыг хүсвэл энэ нийтлэлд оруулсан аргыг ашиглаж болно. Энэ нь гараар тоолох шаардлагагүй бөгөөд үүнийг хурдан хугацаанд хийхэд тусална.

Олон хэрэглэгчид Outlook хуанли дээр ихэнх үйл ажиллагаагаа бүртгэхэд дассан байдаг. Түүнчлэн, тэдгээрийг илүү хялбар удирдах, ялгахын тулд тэд тус бүрт ангилал оноодог. Энэ тохиолдолд зарим хэрэглэгчид өнгөний ангилал бүрт хуанлийн зүйлс дээр зарцуулсан нийт хугацааг харуулсан тайлан гаргахыг хүсдэг. Гараар тоолж, оруулах нь эргэлзээгүй төвөгтэй байдаг. Тиймээс энд бид энэ ажлыг энгийн товшилтоор хэрхэн хийж болохыг хуваалцах болно.

Өнгө ангилал тус бүрт томилолтонд зарцуулсан нийт хугацааг экспортлох

1. Эхний ээлжинд Outlook програмаа ажиллуулна уу.
2. Дараа нь Outlook цонхонд орсны дараа та "Alt + F11" товчлууруудыг дарж болно.
3. Дараа нь та “Програмд ​​зориулсан Microsoft Visual Basic” цонхонд нэвтрэх боломжтой болно.
4. Дараа нь та “Microsoft Excel Object Library”-г идэвхжүүлэх шаардлагатай. Үүнийг хийхийн тулд “Tools” > “Reference” дээр дарна уу.
5. Дараа нь та ашиглагдаагүй байгаа модулийг олж нээх хэрэгтэй.
6. Үүний дараа та дараахь VBA кодыг энэ модуль руу хуулах хэрэгтэй.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Эцэст нь та энэ макрог хэрэгслийн самбар дээрх "Run" дүрс дээр дарах эсвэл "F5" товчлуур дээр дарах замаар идэвхжүүлж болно.
8. Дараа нь танд тодорхой хуанли сонгохыг шаардах болно.
9. Та "OK" -г сонгоод дарсны дараа макро үргэлжлүүлэн ажиллана. Үүнийг дуусгасны дараа цаана нь харагдах шинэ Excel файл байх болно.
10. Та үүнд нэвтрэх боломжтой. Энэ нь дараахь дэлгэцийн агшин шиг харагдах болно.

Таны хэтийн төлөвийн эргэн тойронд гарч болзошгүй аюул заналхийллийг анхааралтай ажигла

Outlook хэрэглэгчид имэйлийн үл мэдэгдэх хавсралт, оруулсан линк, хүний ​​алдаа гэх мэт бүх болзошгүй эрсдлийг анхаарч үзэх хэрэгтэй. Үгүй бол таны Outlook хэзээ ч эвдэрч болзошгүй юм. Түүнчлэн Outlook-ийн өгөгдлийг тогтмол нөөцлөх, засварын тусгай хэрэгслийг хадгалах нь зайлшгүй шаардлагатай асуудал юм. DataNumen Outlook Repair хамгийн их зөвлөдөг засварлах хэрэгслүүдийн нэг юм. Энэ нь чадна Outlook програмыг засах асуудлууд.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. гэмтсэн mdf програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com