Outlook имэйлийн бүх зургийн хавсралтыг Excel-ийн ажлын хуудсанд хэрхэн хурдан экспортлох вэ

Outlook шийдлүүд Есдүгээр сарын 29, 2025

Хэрэв та Outlook имэйлийн бүх зургийн хавсралтыг Excel-ийн ажлын хуудсанд хурдан экспортлохыг хүсвэл энэ нийтлэлийг үзнэ үү. Гар аргаар экспортлохоос илүү үр дүнтэй аргыг эндээс харуулах болно.

Та олон тооны зургийн хавсралт агуулсан имэйл хүлээн авахдаа, хэрэв та тэдгээрийг Excel дээр тайлан үүсгэхэд ашиглахыг хүсвэл эдгээр зургийг Excel ажлын хуудас руу багцаар нь экспортлох аргыг хүсэх хэрэгтэй. Одоо бид танд энэ аргыг доор танилцуулах болно.

Бүх имэйлийн зургийн хавсралтыг Excel-ийн ажлын хуудсанд экспортлох

Эхлэхийн тулд Outlook програм дээрээ хэвийн байдлаар хандана уу.
Дараа нь Outlook цонхонд "Alt + F11" товчны товчлуурыг дарахад "Microsoft Visual Basic for Applications" цонх гарч ирнэ.
Энэ дэлгэц дээр та ашиглагдаагүй байгаа модулийг нээх эсвэл шинээр шинээр оруулах хэрэгтэй.
Дараа нь та доорх VBA кодын хэсгийг энэ модуль руу хуулах хэрэгтэй.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

Үүний дараа та макроос гарах боломжтой.
Дараа нь энэ файлыг Quick Access Toolbar дээр нэмэхийн тулд "File"> "Options"> "Quick Access Toolbar" руу орно уу.
Эцэст нь та энэ макроыг яг одоо туршиж үзэх боломжтой.

Нэгдүгээрт, эх имэйлийг сонгож эсвэл нээнэ үү.
Дараа нь Quick Access Toolbar дээрх макро товчийг дарна уу.
Макро дуусахад та Excel-ийн ажлын хуудсыг дараахь дэлгэцийн агшин шиг харуулах болно.

Outlook файлыг авлигаас хамгаалах

Outlook нь авлигад өртөмтгий гэдгийг мэддэг. Тиймээс Outlook хэлбэрийн авлигыг хэрхэн хамгаалахаа ойлгох хэрэгтэй. Нэгдүгээрт, вирусын довтолгоог хаахын тулд вирусны эсрэг програм суулгаж, үл мэдэгдэх хавсралтыг хэзээ ч татаж авахгүй байх хэрэгтэй. Үүнээс гадна, бид хүчтэй засах хэрэгслийг барьж авах нь илүү дээр юм DataNumen Outlook RepairЭнэ нь дараах тохиолдолд хамгийн үр дүнтэй эмчилгээг санал болгож чадна. Авлигын төлөв байдал.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. sql сэргээх програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com