Олон Outlook имэйл дэх бүх гипер холбоосыг Excel рүү хэрхэн хурдан экспортлох вэ

Нэг буюу хэд хэдэн имэйл дэх бүх холбоосыг задлах шаардлагатай үед тэдгээрийг нэг нэгээр нь хуулах нь тэнэг хэрэг юм. Энэ бичлэг нь танд олон имэйл дэх бүх холбоосыг Excel руу хурдан экспортлох аргыг заах болно.

Таны илгээсэн бүх имэйлийн холбоосыг бүртгэх гэх мэт зарим шалтгааны улмаас та гипер холбоосыг задлах хэрэгтэй болно. Ямар ч эргэлзээгүйгээр тэдгээрийг гар аргаар задлах, хуулахыг зөвлөдөггүй. Та VBA ашиглах гэх мэт илүү ухаалаг хандлагыг хүсэх ёстой. Энд бид олон цахим шуудангийн бүх холбоосыг Excel рүү хялбархан товшилтоор экспортлох боломжтой VBA кодын ийм хэсгийг хуваалцах болно.

Олон имэйл дэх бүх гипер холбоосыг Excel рүү экспортлох

1. Эхлэхийн тулд Outlook програмаа ердийнхөөрөө ажиллуулна уу.
2. Дараа нь Outlook цонхонд та "Alt + F11" товчийг дарах хэрэгтэй.
3. Та нэг дор Outlook VBA засварлагч руу нэвтрэх боломжтой болно.
4. Үүний дараа та “Microsoft Word Object Library” болон “Microsoft Excel Object Library”-г идэвхжүүлэх хэрэгтэй. “Tools” > “References” дээр дараад гарч ирэх харилцах цонхонд тэдгээрийг идэвхжүүлнэ үү.
5. Дараа нь та ашиглагдаагүй модулийг нээх хэрэгтэй бөгөөд үүнд та доорх VBA кодыг энэ модуль руу хуулах хэрэгтэй.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Үүний дараа та одоогийн VBA засварлагч цонхноос гарах боломжтой.
7. Дараа нь "Outlook Options" руу нэвтэрч, Quick Access Toolbar-д шинээр нэмсэн макрог хурдан нэвтрэх хэрэгслийн самбарт нэмнэ үү.
8. Эцэст нь та буудаж болно:

• Юуны өмнө цахим шуудангийн жагсаалтаас гипер холбоосыг нь задлахыг хүссэн имэйлээ сонгоно уу.
• Дараа нь Quick Access Toolbar дээрх макро товчлуур дээр дарна уу.
• Макро дууссаны дараа та доорх зураг шиг Excel файлыг авах болно.

Outlook-ийн гэнэтийн асуудлуудыг засах

Outlook-той холбоотой асуудлууд үе үе ямар ч шинж тэмдэггүйгээр гарч болно. Гэхдээ жижиг алдаануудын хувьд Outlook нь энгийн дахин ачаалах эсвэл түүний тусламжтайгаар сэргээгдэж болно. ирсэн хайрцаг засах хэрэгсэл. Гэхдээ ямар нэгэн ноцтой асуудал тулгарвал дотоод арга нь үр нөлөө үзүүлэхгүй. Энэ үед таны эцсийн арга зам бол мэдээж илүү нэр хүндтэй, бат бөх хэрэгсэл, жишээ нь DataNumen Outlook Repair.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. гэмтсэн mdf програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com