Windows хавтас дахь хамгийн сүүлд өөрчилсөн файлыг Outlook имэйлдээ хэрхэн хурдан хавсаргах вэ

Заримдаа та Windows-ын тодорхой хавтсанд хамгийн сүүлд өөрчилсөн файлыг хурдан олж, Outlook имэйл рүү хавсаргах хэрэгтэй. Энэ тохиолдолд та энэ нийтлэлд дурдсан аргыг ашиглаж болно.

Зарим хэрэглэгчид Outlook нь Windows хавтсанд байгаа хамгийн сүүлд өөрчлөгдсөн файлыг, тухайлбал хамгийн сүүлд үүсгэсэн, өөрчлөгдсөн эсвэл хадгалсан файлыг хурдан олж, имэйлд хавсаргахыг хүсдэг. Гэсэн хэдий ч Outlook нь ийм шууд бөгөөд уугуул функцийг санал болгодоггүй. Тиймээс доор бид үүнийг хялбархан хийж болох VBA кодын хэсгийг танилцуулах болно.

Windows хавтас дахь хамгийн сүүлд өөрчилсөн файлыг имэйлд хавсаргана уу

1. Хамгийн эхэнд та Outlook програмаа ажиллуулах хэрэгтэй.
2. Дараа нь Outlook-ийн үндсэн цонхонд орсны дараа "Alt + F11" товчийг дарж болно.
3. Дараа нь та Outlook VBA засварлагчийн цонхонд амжилттай нэвтрэх болно.
4. Дараа нь та ашиглагдаагүй модулийг олж нээх хэрэгтэй.
5. Дараа нь энэ модулийн цонхонд дараах VBA кодыг хуулж буулгана уу.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Үүний дараа та VBA засварлагчийн одоогийн цонхноос гарч, хурдан нэвтрэх хэрэгслийн самбар эсвэл мессежийн цонхны туузанд шинэ макро нэмэх боломжтой.
7. Дараа нь та Outlook-ын макро аюулгүй байдлын түвшинг бага болгож өөрчлөх хэрэгтэй.
8. Эцэст нь та хичээгээд үзээрэй.

• Нэгдүгээрт, ердийнхөөрөө шинэ Outlook имэйл үүсгэж, бичээрэй.
• Дараа нь доорх зураг шиг Quick Access Toolbar дээрх макро товчийг дарна уу.
• Дараа нь та Windows-ийн эх фолдерыг сонгоод "OK" дээр дарна уу.
• Хэрэв сонгосон Windows хавтсанд ийм файл байгаа бол та дараах дэлгэцийн агшин шиг сануулга авах болно.
• Та "Тийм" гэснийг товшвол энэ файлыг нэг дор хавсаргах болно.

Outlook-ийн асуудлыг аль болох хурдан шийдээрэй

Ямар нэгэн Outlook асуудалтай тулгарвал аль болох хурдан шийдвэрлэхийг зөвлөж байна. Энэ тохиолдолд та бат бөх бэлтгэсэн нь дээр Outlook засах гэх мэт хэрэгслийг урьдчилан ашиглах DataNumen Outlook Repair. Энэ нь PST алдааг засах, Outlook-ийн өгөгдлийг үр дүнтэйгээр хадгалах чадвартай.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. гэмтсэн mdf програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com