Олон Outlook мессеж (.msg) файлаас бүх хүлээн авагчийг хэрхэн хурдан задлах вэ

Outlook шийдлүүд Есдүгээр сарын 29, 2025

Зарим хэрэглэгчид Outlook имэйлээс хадгалагдсан олон Outlook мессежийн файлаас бүх хүлээн авагчийг хурдан гаргаж авахыг хүсдэг. Одоо энэ хost хурдан арга барилыг хуваалцахын тулд үүнийг харна.

Нэг Outlook мессежийн файлаас хүлээн авагчдыг задлахын тулд та хоёр товшиж нээж, нээгдсэн мессежийн цонхонд хүлээн авагчдыг хуулж болно. Гэхдээ хэрэв та Outlook мессежийн файлуудын багцтай ажиллах шаардлагатай бол гарын авлагын арга нь хангалттай үр дүнтэй биш юм. Тиймээс та илүү үр дүнтэй аргыг хайж олох боломжтой. Энд бид танд ийм нэгийг танилцуулах болно. Үүний дэлгэрэнгүйг уншина уу.

Олон Outlook мессеж (.msg) файлаас бүх хүлээн авагчийг задлах

Учир ньtart, "-ын дагуу Outlook VBA засварлагч руу нэвтрэх.Таны Outlook дээр VBA кодыг хэрхэн ажиллуулах вэ".
Дараа нь дараах VBA кодыг хоосон модуль руу хуулж буулгана уу.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

Дараа нь курсорыг эхний дэд программд шилжүүлнэ үү.
Дараа нь "Run" товчийг дарж эсвэл "F5" товчийг дарна уу.
Дараа нь гарч ирэх харилцах цонхноос эх Outlook мессеж (.msg) файлуудыг агуулсан Windows хавтсыг сонгоно уу.
Сонгосны дараа "OK" дээр дарж макро үргэлжлүүлэн ажиллахыг зөвшөөрнө үү.
Макро ажиллаж дуусахад дараах дэлгэцийн агшинд үзүүлсэн шиг задалсан бүх хүлээн авагчийн имэйл хаягийг харуулсан мессеж гарч ирнэ.

Outlook мэдээллээ аюулаас хамгаалаарай

Outlook өгөгдөл нь авлигад өртөмтгий байдаг. Тиймээс Outlook-ийн өгөгдлийг хамгаалах нь нэлээд төвөгтэй ажил юм. Энэ нь танаас Outlook-ийн өгөгдлийг тогтмол нөөцлөхөд тууштай байхыг шаарддаг. Боломжтой бол туршлагатай, мэргэжлийн хэтийн төлөвийг бэлтгэхийг зөвлөж байна PST засвар хэрэгсэл, гэх мэт DataNumen Outlook Repair, ингэснээр та Outlook-ийн эвдрэлийн үед яаралтай, цаг алдалгүй аврах боломжтой болно.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. сэргээх Sql Server програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com