Outlook VBA-ээр дамжуулан тодорхой ирсэн имэйлүүдээс суулгагдсан зургуудыг хэрхэн автоматаар гаргаж авах вэ

Хэрэв та Outlook-ийг орж ирж буй имэйлүүдээс суулгасан зургуудыг автоматаар задалж хадгалахыг хүсвэл та энэ нийтлэлийг үзнэ үү. VBA кодоор үүнийг хэрхэн хэрэгжүүлэх талаар бид танд заах болно.

Зарим хэрэглэгчид орж ирсэн имэйлүүдээс суулгагдсан зургуудыг гаргаж аваад тодорхой Windows хавтсанд хадгалах шаардлагатай байдаг. Тэр болгонд гараар хийх нь маш хэцүү байдаг. Тиймээс олон хүн Outlook auto-д үүнийг хэрэгжүүлэх боломжийг олгох хурдан бөгөөд тохиромжтой аргыг сурахыг тэсэн ядан хүлээж байна. Одоо бид ийм аргыг та бүхэнтэй хуваалцах болно.

Тодорхой ирж ​​буй имэйлээс суулгагдсан зургийг автоматаар гаргаж авах

1. Нэгдүгээрт, ердийн байдлаар Outlook програмаа ажиллуулаарай.
2. Дараа нь Outlook VBA редакторыг ердийн байдлаар t “Таны Outlook дээр VBA кодыг хэрхэн ажиллуулах вэ".
3. Дараа нь дараахь VBA кодыг хуулж, “ThisOutlookSession” төсөлд оруулна уу.

Public WithEvents objInbox As Outlook.Folder
Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Set objInboxItems = objInbox.Items
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.Attachments
    Dim objAttachment As Outlook.Attachment
    Dim strWindowsFolder As String
    Dim i As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Specify the emails as per your needs
       If objMail.Importance = olImportanceHigh Then
          Set objAttachments = objMail.Attachments
 
          'Specify the windows folder
          strWindowsFolder = "E:\" & objMail.Subject & Format(Now, "yymmddhhmmss")
          MkDir (strWindowsFolder)
 
          'Save all embedded images to the folder
          For i = 1 To objAttachments.Count
              Set objAttachment = objAttachments.Item(i)
              If IsEmbedded(objAttachment) = True Then
                 objAttachment.SaveAsFile strWindowsFolder & "\" & objAttachment.FileName
              End If
          Next
      End If
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

4. Үүний дараа "Application_Startup" дэд програм руу орно уу.
5. Эцэст нь “F5” товчийг дарж энэ макро идэвхжүүлнэ үү.
6. Одооноос эхлэн ирсэн имэйл хайрцагт тодорхой шинэ имэйл ирэх бүрт суулгагдсан зургуудыг дараахь дэлгэцийн агшинд харуулсны дагуу тодорхой Windows хавтсанд хадгалах болно.

Том хавсралтыг тогтмол цэвэрлэж байх хэрэгтэй

Outlook-оосоо том хавсралтуудыг тогтмол цэвэрлэхийг зөвлөж байна. Энэ нь таны Outlook файлыг зохих хэмжээгээр хадгалах зорилготой юм. Том Outlook файл нь эвдрэлд илүү өртөмтгий байдаг. Таны мэдэж байгаагаар PST-ийн эвдрэлийг сайн шийдвэрлэхэд нэлээд хэцүү байдаг. Магадгүй та эхлээд имэйлийн засварлах хэрэгслээр үүнийг засахыг оролдох байх. Гэсэн хэдий ч ихэнх тохиолдолд энэ нь ажиллахгүй. Таны цорын ганц арга зам бол мэргэшсэн програм юм. PST засвар хэрэгсэл, гэх мэт DataNumen Outlook Repair, эсвэл холбогдох мэргэжлийн нөхөн сэргээх үйлчилгээ.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. mdf засах програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com