Хэрхэн олон ноорог имэйлийг Outlook загвар болгон багцаар хадгалах вэ

Outlook шийдлүүд Есдүгээр сарын 29, 2025

Магадгүй та хэд хэдэн ноорог имэйл үүсгэсэн бөгөөд тэдгээрийг дахин ашиглах болно гэж найдаж байна олон удаа. Хэрэв тийм бол яагаад тэдгээрийг Outlook загвар болгон хадгалахгүй байна вэ? Энэ нийтлэл нь VBA-ээр дамжуулан үүнийг нэг дор хийхийг заах болно.

Анхдагч байдлаар, Outlook нь хэрэглэгчдэд зөвхөн нэг имэйлийг нэг дор загвар болгон хадгалахыг зөвшөөрдөг. Өөрөөр хэлбэл, та олон ноорог имэйлийг бөөнөөр нь загвар болгон хадгалах боломжгүй. Таны харж байгаагаар нэгээс олон имэйл сонгоод "Файл" > "Хадгалах" хэсэгт очиход "Хадгалах төрөл" жагсаалтаас "Outlook загвар" форматыг олох боломжгүй, зөвхөн "Зөвхөн текст" боломжтой. Гэхдээ бид үүнийг хэрхэн бөөнөөр нь ойлгохыг дараахь зүйлд танилцуулах болно.

Олон ноорог имэйлийг Outlook загвар болгон хадгалах

Хамгийн эхэнд Outlook VBA засварлагчийг ажиллуул.
Шинэ "Microsoft Visual Basic for Applications" цонхонд доорх VBA кодыг хуулж буулгана уу.

Sub SaveMultipleDraftsAsTemplates()
    Dim objSelection As Outlook.Selection
    Dim i As Long
    Dim strTemplateFolder As String
    Dim objMail As Outlook.MailItem
    Dim strSubject As String
 
    'Get all selected mails
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
       'Get the default folder for saving Outlook Templates
       strTemplateFolder = CStr(Environ("USERPROFILE")) & "\Documents\UserTemplates\"
 
       'Save each mail as template
       For i = objSelection.Count To 1 Step -1
           If objSelection(i).Class = olMail Then
              Set objMail = objSelection(i)
              If objMail.Subject <> "" Then
 
                 'Remove unsupported characters
                 strSubject = objMail.Subject
                 strSubject = Replace(strSubject, "/", " ")
                 strSubject = Replace(strSubject, "\", " ")
                 strSubject = Replace(strSubject, ":", "")
                 strSubject = Replace(strSubject, "?", " ")
                 strSubject = Replace(strSubject, Chr(34), " ")
 
                 objMail.SaveAs strTemplateFolder & strSubject & ".oft", olTemplate
              Else
                 objMail.SaveAs strTemplateFolder & "Template" & i & ".oft", olTemplate
              End If
           End If
       Next
 
       'Open the folder of Templates
       Shell "Explorer.exe" & " " & strTemplateFolder, vbNormalFocus
    End If
End Sub

Үүний дараа, дараа нь тав тухтай байлгахын тулд энэ макрог Quick Access Toolbar (QAT) дээр хавсаргахыг зөвлөж байна. Нарийвчилсан алхмуудын талаар та уншиж болно "Таны Outlook дээр VBA кодыг хэрхэн ажиллуулах вэ"
Эцэст нь та доорх үйлдлүүдийг дагаж зураг авах боломжтой.

Эхлээд загвар болгон хадгалах ноорог имэйлийг сонгоно уу.
Дараа нь QAT дээрх макро товчийг дарна уу.
Макро дуусахад өгөгдмөл Outlook загваруудыг хадгалах Windows хавтас гарч ирнэ. Сонгосон ноорог имэйлийн загварууд тэнд байгааг харж болно.

Ирсэн имэйлийг засах хэрэгсэл амжилтгүй болсон хэвээр байна

Дотоод Outlook засах хэрэгсэл болох Scanpst-ийн тухай ярихад олон тооны хэрэглэгчид үүнийг үнэлэх болно. Энэхүү хэрэгсэл нь Outlook дээрх ихэнх жижиг асуудлуудыг шийдвэрлэх чадвартай нь дамжиггүй. Гэсэн хэдий ч энэ нь бүрэн төгс биш юм. Энэ нь бүтэлгүйтэж, олон алдаа гаргаж болно. Жишээлбэл, хүнд хэлбэрийн үед Авлигын төлөв байдал, энэ нь эвдэрсэн PST файлыг засах боломжгүй байна. Энэ тохиолдолд танд илүү хүчирхэг, шилдэг гуравдагч талын хэрэгслийг ашиглахаас өөр сонголт байхгүй. DataNumen Outlook Repair.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. sql сэргээх програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com