Таны Outlook дахь бүх уншсан баримтыг хэрхэн багцаар устгах вэ

Хүлээн авагчид таны имэйлийг уншсан эсэхийг баталгаажуулахын тулд та имэйл бичихдээ уншсаны баримт хүсэх боломжтой. Энэ тохиолдолд таны шуудангийн хайрцаг ийм уншсан баримтаар дүүрч магадгүй. Одоо энэ бичлэгт тэдгээрийг хэрхэн бүрмөсөн устгах талаар заах болно.

Нийтлэлийг уншаадТаны Outlook дахь бүх хүргэлтийн баримтыг хэрхэн багцаар устгах вэ“, Уншсан бүх баримтыг бөөнөөр нь устгах хандлагын талаар та бодож магадгүй юм. Үнэн хэрэгтээ хоёр төрлийн баримтын ялгавартай ялгаа нь тэдний харьяалал юм. Хүргэлтийн баримт нь "Хүргэгдсэн" гэсэн агуулгатай, харин уншсан баримт нь "Унших" гэсэн үг юм. Тиймээс та уншсан бүх баримтыг багцаар устгах ижил аргыг ашиглаж болно. Дараахь зүйлүүдэд бид тодорхой алхамуудыг нарийвчлан зааж өгөх болно.

Багцаар уншсан бүх баримтыг устгана уу

1. Эхэндээ Outlook-оо эхлүүлээрэй.
2. Дараа нь "Alt + F11" -ээр дамжуулан Outlook VBA редактор руу орно уу.Таны Outlook дээр VBA кодыг хэрхэн ажиллуулах вэ".
3. Дараа нь шинэ цонхонд хоосон модулийг нээгээд дараах кодыг оруулна уу.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Үүний дараа эхний дэд програм дээр дарна уу.
5. Эцэст нь “F5” товчийг дарна уу.
6. Макро нь таны Outlook дээрх бүх уншсан баримтыг устгахын тулд нэг дор ажиллах болно.
7. Энэ нь дууссаны дараа та доорх дэлгэцийн агшин шиг үр дүнгийн талаар мэдэгдэл авах болно.
8. Одоогийн байдлаар та шуудангийн хавтасаа шалгаж болно. Бүх уншсан баримтууд алга болсон.

Outlook өгөгдлийг хамгаалах

Хэдийгээр Outlook файл нь авлигад өртөмтгий боловч бид үүнийг хамгаалах арга хэмжээ авч болно. Жишээлбэл, бид Outlook файлыг бага хэмжээгээр хадгалж, хор хөнөөлтэй хүчин зүйлээс хамгаалж, нөөцлөх ажлыг тогтмол хийх ёстой. Эцэст нь хэлэхэд та PST-ийг засах гадаад хүчирхэг хэрэгсэл бэлтгэх нь дээр DataNumen Outlook Repair. Энэ нь засахад маш их нөлөө үзүүлэх болно авлигад автсан Outlook файл.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. квадрат засвар програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com