Тодорхой огнооны хүрээнд төлөвлөсөн бүх Outlook уулзалтыг хэрхэн багцаар цуцлах вэ

Хэрэв та Outlook дээрх тодорхой огнооны хүрээнд төлөвлөсөн бүх уулзалтыг цуцлахыг хүсвэл энэ нийтлэлд дурдсан арга хэрэгслийг ашиглаж болно. Энэ нь таныг ийм уулзалтуудыг гараар хайх, цуцлахаас аварч чадна.

Хэрэв та ямар нэг шалтгааны улмаас тодорхой хугацаанд зохион байгуулагдах уулзалтуудыг зохион байгуулж, оролцох боломжгүй бол эдгээр бүх уулзалтыг цуцалж болно. Ерөнхийдөө та эхлээд тэдгээрийг олж мэдээд дараа нь нэг нэгээр нь цуцлах хэрэгтэй. Энэ нь нэлээд төвөгтэй байх болно. Тиймээс, бид танд илүү тохиромжтой өөр аргыг хуваалцах болно.

Тодорхой огнооны хүрээнд товлогдсон бүх уулзалтыг багцаар цуцална

1. Хамгийн эхэнд Outlook програмаа эхлүүлээрэй.
2. Дараа нь Outlook дээр та "Alt + F11" товчийг дарах хэрэгтэй.
3. Дараа нь та "Microsoft Visual Basic for Applications" цонх руу орох болно.
4. Энэ цонхонд та ашиглагдаагүй модулийг нээх эсвэл шинээр оруулах хэрэгтэй.
5. Дараа нь та дараахь VBA кодыг энэ модуль руу хуулж болно.

Sub BatchCancelAllMeetingsInSpecificDateRange()
    Dim dStartDate As Date
    Dim dEndDate As Date
    Dim objCalendarFolder As Outlook.folder
    Dim objItems As Outlook.Items
    Dim objItemsInDateRange As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim objResponse As Outlook.MeetingItem
 
    'Specify the start date and end date
    dStartDate = InputBox("Enter the start date:", , "10/1/2017")
    dEndDate = InputBox("Enter the end date:", , "10/8/2017")
 
    If dStartDate <> #1/1/4501# And dEndDate <> #1/1/4501# Then
       'Select a calendar folder
       Set objCalendarFolder = Outlook.Application.Session.PickFolder
       Set objItems = objCalendarFolder.Items
       objItems.IncludeRecurrences = True
       objItems.Sort "[Start]"
 
       'Get the appointments in the specific date range
       strFilter = "[Start] >= " & Chr(34) & dStartDate & " 00:00 AM" & Chr(34) & " AND [End] <= " & Chr(34) & dEndDate & " 11:59 PM" & Chr(34)
       Set objItemsInDateRange = objItems.Restrict(strFilter)
 
       objItemsInDateRange.Sort "[Start]"
       For Each objAppointment In objItemsInDateRange
           'Cancel the meetings in this date range
           If objAppointment.MeetingStatus = olMeeting Then
              If objAppointment.Organizer = Outlook.Session.CurrentUser Then
                 objAppointment.MeetingStatus = olMeetingCanceled
                 objAppointment.Save
                 objAppointment.Send
                 objAppointment.Delete
              Else
                 Set objResponse = objAppointment.Respond(olMeetingDeclined)
                 objResponse.Send
                 objAppointment.Delete
              End If
            End If
       Next
    End If
End Sub

6. Эцсийн эцэст та энэ макро яг одоо ажиллуулж болно.

• Одоогийн макро цонхонд "F5" товчийг дарна уу.
• Дараа нь та огнооны мужийг зааж өгөх шаардлагатай болно.
• Үүний дараа өөр харилцах цонх гарч ирэх бөгөөд энэ нь таныг календарийн эх хавтсыг сонгоод "OK" дээр дарна уу.
• Эцэст нь, макро дууссаны дараа та тодорхой огнооны муж дахь бүх уулзалтууд цуцлагдсаныг харж болно.
• "Илгээсэн зүйлс" хавтсаас та доорх дэлгэцийн зураг шиг уулзалт цуцлагдсаныг харж болно.

Outlook алдааг засах

Хэрэв та Outlook-ийг хэдэн арван жил ашигласан бол хэд хэдэн алдаатай тулгарсан байх ёстой. Аз болоход Outlook нь суурилуулсан засварын хэрэгсэлтэй ирдэг - Scanpst. Та үүнийг ашиглаж болно Outlook засах алдаанууд. Гэсэн хэдий ч, хэрэв энэ нь амжилтгүй болвол таны хамгийн сүүлчийн арга бол гадны засварын хэрэгсэл юм DataNumen Outlook RepairЭнэ нь Outlook файлыг сканнердаж, ихэнх алдааг засахаас гадна гэмтсэн Outlook өгөгдлийг хялбархан сэргээж чадна.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. sql засах програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com