Янз бүрийн өнгөний категорийн Outlook уулзалтын өөр сануулах хугацааг хэрхэн автоматаар тохируулах вэ

Хэрэв та Outlook уулзалтыг өнгөний төрлөөр нь ангилж байгаа бөгөөд өөр өөр өнгөний ангиллын уулзалтын сануулах хугацааг өөрөөр тохируулахыг хүсч байвал энэ нийтлэлийг үзнэ үү. Энд бид танд Outlook VBA -ийн тусламжтайгаар үүнийг хэрэгжүүлэхийг заах болно.

Жишээлбэл, та уулзалтуудыг хоёр бүлэгт хувааж байна. Нэг нь уулзалтын байршил хэт хол байгаа тул "Гадаад" өнгөний ангилалд, нөгөө нь байршил яг энд байгаа тул "Гадаад" өнгөний ангилалд байна. Одоо та Outlook нь "гадаа" уулзалтын сануулах хугацааг эхлэхээс 1 цагийн өмнө, "гадаа" уулзалт эхлэхээс 15 минутын өмнө автоматаар тохируулах боломжтой байхыг хүсэж байна. Энэ шаардлагыг харгалзан үзвэл бид цаашид хурдан аргыг хуваалцах болно.

Янз бүрийн өнгөний ангиллын уулзалтанд зориулсан өөр сануулагчийг автоматаар тохируулах

1. Эхлэхийн тулд Outlook програмаа ажиллуулна уу.
2. Дараа нь "Alt + F11" товчлууруудыг дарж VBA засварлагчийн цонхонд очно уу.
3. Дараа нь дараагийн цонхонд доорх VBA кодыг хуулж "ThisOutlookSession" төсөлд оруулна уу.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Дараа нь та "Application_Startup" дэд програм руу ороод "F5" товчийг дарж энэ макрог ажиллуулах хэрэгтэй.
5. Түүнээс хойш үндсэн хуанлид шинэ уулзалт нэмэх эсвэл одоо байгаа уулзалтыг өөрчлөх болгонд Outlook уулзалтын ангиллыг автоматаар шалгаж, өөр сануулах хугацааг автоматаар тохируулах болно.

Outlook алдааг арилгах

Outlook-д үе үе янз бүрийн асуудал гарч болзошгүй. Тиймээс хэрэглэгчид Outlook-ийн асуудлыг хэрхэн шийдвэрлэх талаар сурах нь маш чухал юм. Эхлээд та Outlook өгөгдлийн нөөцлөлтийг тогтмол хийх нь дээр. Түүнчлэн, хэрэв боломжийн үнэтэй бол хүчирхэг нөөцлөлтийг хадгалахыг зөвлөж байна. Outlook засвар гэх мэт ойролцоох хэрэгсэл DataNumen Outlook Repair. Энэ нь таны PST файлыг скан хийж Outlook -ийн асуудлуудыг олж, дараа нь хялбархан шийдвэрлэх боломжтой.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. sql сэргээх програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com