Outlook VBA ашиглан Excel файл руу ирж буй имэйлийн мэдээллийг хэрхэн автоматаар экспортлох вэ

Outlook шийдлүүд Есдүгээр сарын 29, 2025

Олон хэрэглэгчид Outlook нь ирж буй имэйлийн үндсэн мэдээллийг Excel файл руу автоматаар экспортлох боломжтой гэж найдаж байна. Энэ нийтлэл нь энэ шаардлагыг судалж, Outlook VBA-ээр дамжуулан хурдан аргыг танилцуулах болно.

Заримдаа имэйлийн статистик гэх мэт зарим шалтгааны улмаас та имэйлээ Excel файл руу экспортлох шаардлагатай болдог. Ерөнхийдөө одоо байгаа имэйлүүдийн хувьд та "Импорт, экспорт" функцийг ашиглан тэдгээрийг Excel рүү нэг дор экспортлох боломжтой. Гэсэн хэдий ч, Outlook нь ирж буй имэйлийг таны шуудангийн хайрцагт ирсэн даруйд нь Excel рүү автоматаар экспортлохыг хүсч магадгүй юм. Outlook-д ийм эх боломж байхгүй нь эргэлзээгүй. Тиймээс та гуравдагч талын нэмэлт хэрэгсэл эсвэл Outlook VBA гэх мэт өөр аргыг ашиглах хэрэгтэй. Энд бид Outlook VBA-г хэрхэн автоматжуулахыг танд заах болно. Алхамууд болон кодын дагуу авахын тулд уншина уу.

Ирж буй имэйлийн мэдээллийг Excel файл руу автоматаар экспортлох

Юуны өмнө та Excel файл үүсгэх хэрэгтэй.

Шинэ Excel файл нээнэ үү.
Дараа нь та "Үгүй" гэж бичих хэрэгтэй. Дараах зураг шиг A1 нүдэнд "Илгээгчийн нэр", В1 нүдэнд "Илгээгчийн имэйл хаяг", D1 нүдэнд "И-мэйл субьект", E1 нүдэнд "Хүлээн авсан цаг" гэсэн мэдээллийг оруулна.
Эцэст нь үүнийг хүссэн нэр болон хавтсандаа хадгална уу.

Үүний дараа та Outlook-г эхлүүлэх хэрэгтэй.
Дараа нь "Alt + F11" товчийг дарснаар VBA засварлагч руу очно.
Дараа нь гарч ирэх цонхны зүүн талд байгаа "ThisOutlookSession" дээр давхар товшино уу.
Дараа нь, "ThisOutlookSession" төслийн цонхонд та дараах VBA кодуудыг хуулж, буулгах хэрэгтэй.

Public WithEvents objMails As Outlook.Items

Private Sub Application_Startup()
    Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objMails_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim strColumnB As String
    Dim strColumnC As String
    Dim strColumnD As String
    Dim strColumnE As String

    If Item.Class = olMail Then
       Set objMail = Item
    End If
 
    'Specify the Excel file which you want to auto export the email list
    'You can change it as per your case
    strExcelFile = "E:\Email\Email Statistics.xlsx"
 
    'Get Access to the Excel file
    On Error Resume Next
    Set objExcelApp = GetObject(, "Excel.Application")
    If Error <> 0 Then
       Set objExcelApp = CreateObject("Excel.Application")
    End If
    Set objExcelWorkBook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorkSheet = objExcelWorkBook.Sheets("Sheet1")
 
    'Get the next empty row in the Excel worksheet
    nNextEmptyRow = objExcelWorkSheet.Range("B" & objExcelWorkSheet.Rows.Count).End(xlUp).Row + 1
 
    'Specify the corresponding values in the different columns
    strColumnB = objMail.SenderName
    strColumnC = objMail.SenderEmailAddress
    strColumnD = objMail.Subject
    strColumnE = objMail.ReceivedTime
 
    'Add the vaules into the columns
    objExcelWorkSheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorkSheet.Range("B" & nNextEmptyRow) = strColumnB
    objExcelWorkSheet.Range("C" & nNextEmptyRow) = strColumnC
    objExcelWorkSheet.Range("D" & nNextEmptyRow) = strColumnD
    objExcelWorkSheet.Range("E" & nNextEmptyRow) = strColumnE
 
    'Fit the columns from A to E
    objExcelWorkSheet.Columns("A:E").AutoFit
 
    'Save the changes and close the Excel file
    objExcelWorkBook.Close SaveChanges:=True
End Sub

Дараа нь та энэ кодонд гарын үсэг зурах хэрэгтэй.
Дараа нь, дахинtart VBA-ийн шинэ төслийг идэвхжүүлэх Outlook.
Эцсийн эцэст, одооноос эхлэн бүх ирсэн имэйлүүд таны Ирсэн имэйл хавтсанд орсон даруйд урьдчилан тохируулсан Excel файл руу автоматаар экспортлогдох болно. Excel файл нь дараах зураг шиг харагдах болно.

Өвдөлттэй PST мэдээллийн эвдрэлээс урьдчилан сэргийлэх

Outlook нь янз бүрийн онцлог шинж чанараараа маш их магтаал хүртсэн. Гэсэн хэдий ч энэ нь эргэлзээгүй гэсэн үг биш юм. Энэ нь ямар ч үед эвдэрч болзошгүй хэвээр байна. Жишээлбэл, хэрэв та Outlook-ээ байнга буруу хаадаг бол таны PST өгөгдөл аюулд өртөх магадлал өндөр байдаг. Энэ тохиолдолд хэрэв та хүсвэл засварын газар өгөгдлийн хувьд та туршлагатай хэрэгсэлд хандах хэрэгтэй DataNumen Outlook Repair.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. mdf-ийг сэргээх програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com