Word хүснэгтийн хоосон мөр, баганыг устгах 3 хурдан арга

Энэ бичлэгт бид танд Word хүснэгтээс хоосон мөр, баганыг устгах 3 хурдан аргыг тайлбарлах болно.

Хүснэгт нь баримт бичигт, ялангуяа янз бүрийн төрлийн өгөгдлийг хадгалахад зайлшгүй шаардлагатай. Заримдаа урт хүснэгт нь нэг хуудаснаас давж, хэд хэдэн хуудаснаас илүү байж болно. Тиймээс хүснэгт урт бөгөөд төвөгтэй болсон бол үүнийг хялбарчлах арга хэмжээ авах боломжтой. Жишээлбэл, та шаардлагагүй хоосон мөр, багануудыг устгаж болно.

Дараах 3 аргыг ашиглаж болно.

Арга 1: Хоосон мөр, баганыг гараар устгана уу

1. Эхлээд хоосон зайд мөр эсвэл багана сонгоно уу.
2. Дараа нь контекст цэсийг авахын тулд баруун товчийг дарна уу. Цэс дээр "Мөр устгах" эсвэл "Баганыг устгах" гэсэн сонголтыг сонгоно уу.

Харамсалтай нь та хэд хэдэн дараалсан бус мөр, баганыг сонгоод хамтад нь устгах боломжгүй. Энэ эрэлт хэрэгцээг та манай өмнөх нийтлэлээс харж болно. Үгийн хүснэгтэн дэх олон мөр эсвэл баганыг багцаар устгах 5 хурдан арга

Арга 2: Хүснэгт дэх бүх хоосон мөр, баганыг багцаар устгах

1-р арга нь хязгаарлалттай. Тиймээс бид танд VBA кодоор дамжуулан хүснэгтийн мөр, баганыг багцлан устгах аргыг санал болгох болно.

1. Эхлээд курсорыг зорилтот хүснэгтийн дотор байрлуулна уу.
2. Хоёрдугаарт, "Alt + F11" товчийг дарж VBA засварлагчийг ажиллуул.
3. Засварлагчаас эхлээд "Хэвийн" төсөл дээр дарна уу.
4. Дараа нь цэсний "Оруулах" таб дээр дарна уу.
5. Унтраах цэснээс “Модуль” -г сонгоно уу.
6. Модуль дээр давхар товшоод нээгээд дараах кодыг оруулна уу:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Эцэст нь цэсийн мөрөнд байрлах "Run" товчийг дарах эсвэл "F5" товчийг дарна уу.

Хэдэн секундын дараа та хүснэгтийн бүх хоосон мөр, багануудыг устгах болно.

Арга 3: Баримт бичгийн бүх хүснэгтийн хоосон мөр, баганыг багцаар устгах

1. Эхлээд макро суулгаж ажиллуулахын тулд 2-р аргын алхмуудыг давтана уу.
2. Зөвхөн энэ удаад тэр макро дараах байдлаар солино уу:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Эвдэрсэн баримт бичгийг сэргээх

Өнөө үед алдагдсан өгөгдлийг буцааж авах олон арга бий. Жишээлбэл, нөөцлөлтийг ашиглах нь таны тэргүүлэх чиглэл хэвээр байна. Хэрэв энэ нь таны хамгийн сүүлийн үеийн мэдээллийг буцааж авах хэрэгцээг хангахгүй бол та дараахыг туршиж үзэж болно. док засвар хэрэгсэл.

Зохиогчийн танилцуулга:

Вера Чен бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. xlsx засвар болон pdf програм хангамжийн бүтээгдэхүүнийг засах. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com